I_DevelopmentProjectRole

@AbapCatalog.sqlViewName: 'DEVPROJROLE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #C, sizeCategory: #XL }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.representativeKey: 'ProjectRoleUUID'
@EndUserText.label: 'PPM Project Role Details'

define view I_DevelopmentProjectRole
  as select from /s4ppm/role as _Role
    inner join   dpr_part    as _Part on _Part.guid = _Role.guid
    inner join   cgpl_task   as _Task on  _Task.guid        = _Role.guid
                                      and _Task.object_type = 'MTG'

{
  key _Role.guid                       as ProjectRoleUUID,
      _Role.project_guid               as ProjectUUID,
      _Role.role_type                  as ProjectRoleType,
      _Role.role_name                  as ProjectRoleName,
      _Part.sort_number                as SortingNumber,
      _Part.work_unit                  as PlannedWorkQuantityUnit,
      @Semantics.quantity.unitOfMeasure : 'PlannedWorkQuantityUnit'
      _Part.work_effort                as PlannedWorkQuantity,
      _Part.vacant                     as IsVacant,
      _Part.rate                       as CostRevenueRateCode,
      _Part.currency                   as ManualRevenueRateCurrency,
      @Semantics.amount.currencyCode : 'ManualRevenueRateCurrency'
      _Part.revenue_rate               as ManualRevenueRate,

      @Semantics.quantity.unitOfMeasure : 'ActualWorkQuantityUnit'
      unit_conversion( quantity => _Part.act_work_effort ,
      source_unit =>  _Part.act_work_unit,
      target_unit => _Part.act_wrk_unit_ext,
      error_handling => 'SET_TO_NULL') as DevProjRoleActualWorkQuantity,

      _Part.act_wrk_unit_ext           as ActualWorkQuantityUnit,

      tstmp_to_dats( _Part.beg_tmstmp ,
                 abap_system_timezone( $session.client,'NULL' ),
                 $session.client,
                 'NULL' )              as PlannedStartDate,
      tstmp_to_dats( _Part.end_tmstmp ,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client,
                       'NULL' )        as DevProjRolePlndFinishDate,

      _Part.participant_id             as ProjectRole,
      _Part.role_function_id           as DevProjRoleFunctionID,
      _Part.location                   as LocationType

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/S4PPM/ROLE",
"CGPL_TASK",
"DPR_PART"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/