I_DefectLocationCodeText

@AbapCatalog.sqlViewName: 'IDEFLOCCDTXR'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE 
@VDM.viewType: #BASIC

@ObjectModel:{
    usageType:{
        dataClass: #CUSTOMIZING,
        serviceQuality: #A,
        sizeCategory: #S
    },
    dataCategory: #TEXT,
    representativeKey: 'DefectLocationCode'
}
@EndUserText.label: 'Defect Location Code Text'
define view I_DefectLocationCodeText as select from qpct 

    association[1..1] to I_DefectLocationCatalog as _DefectLocationCatalog on $projection.DefectLocationCatalog = _DefectLocationCatalog.DefectLocationCatalog
    association[1..1] to I_DefectLocationCodeGroup as _DefectLocationCodeGroup on   $projection.DefectLocationCatalog =  _DefectLocationCodeGroup.DefectLocationCatalog and
                                                                                    $projection.DefectLocationCodeGroup = _DefectLocationCodeGroup.DefectLocationCodeGroup
    association[1..1] to I_DefectLocationCode as _DefectLocationCode on $projection.DefectLocationCatalog =  _DefectLocationCode.DefectLocationCatalog and
                                                                        $projection.DefectLocationCodeGroup = _DefectLocationCode.DefectLocationCodeGroup and
                                                                        $projection.DefectLocationCode = _DefectLocationCode.DefectLocationCode                                                                                  
                                                                                    
    association[1..1] to I_Language as _Language    on $projection.Language = _Language.Language
    
{
    @ObjectModel.foreignKey.association: '_DefectLocationCatalog'
    key cast( katalogart as vdm_qfeocat preserving type ) as DefectLocationCatalog,
    @ObjectModel.foreignKey.association: '_DefectLocationCodeGroup'
    key cast( codegruppe as vdm_qfeogrp preserving type ) as DefectLocationCodeGroup,
    @ObjectModel:{
        foreignKey.association: '_DefectLocationCode',
        text.element: ['DefectLocationCodeText']
    }
    key cast( code as vdm_qfeocod preserving type )        as DefectLocationCode,
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key sprache     as Language,
    
    @Semantics.text: true
    cast( kurztext as vdm_qfeocod_text preserving type )    as DefectLocationCodeText,
    
    _DefectLocationCatalog,
    _DefectLocationCodeGroup,
    _DefectLocationCode,
    _Language
       
} where 
    ( 
//      katalogart = 'B' or //Object Parts

      katalogart = 'E'    //Defect Locations

    ) 
    and qpct.version    = '000001' 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QPCT"
],
"ASSOCIATED":
[
"I_DEFECTLOCATIONCATALOG",
"I_DEFECTLOCATIONCODE",
"I_DEFECTLOCATIONCODEGROUP",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/