I_DefectCauseCodeText

DDL: I_DEFECTCAUSECODETEXT SQL: IDEFCACODET Type: view BASIC

Defect Cause Code Text

I_DefectCauseCodeText is a Basic CDS View that provides data about "Defect Cause Code Text" in SAP S/4HANA. It reads from 1 data source (qpct) and exposes 6 fields with key fields DefectCauseCodeGroup, DefectCauseCode, Language. It has 2 associations to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
qpct qpct from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_DefectCauseCodeGroup _DefectCauseCodeGroup $projection.DefectCauseCodeGroup = _DefectCauseCodeGroup.DefectCauseCodeGroup
[1..1] I_DefectCauseCode _DefectCauseCode $projection.DefectCauseCodeGroup = _DefectCauseCode.DefectCauseCodeGroup and $projection.DefectCauseCode = _DefectCauseCode.DefectCauseCode

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName IDEFCACODET view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Defect Cause Code Text view
AccessControl.authorizationCheck #CHECK view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.representativeKey DefectCauseCode view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.dataCategory #TEXT view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY DefectCauseCodeGroup
KEY DefectCauseCode
KEY Language qpct sprache
DefectCauseCodeText
_DefectCauseCodeGroup _DefectCauseCodeGroup
_DefectCauseCode _DefectCauseCode 
@AbapCatalog.sqlViewName: 'IDEFCACODET'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Defect Cause Code Text'
@AccessControl.authorizationCheck: #CHECK
@VDM: {
    viewType:#BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
    representativeKey: 'DefectCauseCode',
    usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #CUSTOMIZING },
    dataCategory: #TEXT
}
@Metadata.ignorePropagatedAnnotations: true
define view I_DefectCauseCodeText as select from qpct 

   association [1..1] to I_DefectCauseCodeGroup as _DefectCauseCodeGroup on $projection.DefectCauseCodeGroup = _DefectCauseCodeGroup.DefectCauseCodeGroup

   association [1..1] to I_DefectCauseCode as _DefectCauseCode           on $projection.DefectCauseCodeGroup = _DefectCauseCode.DefectCauseCodeGroup
                                                                        and $projection.DefectCauseCode      = _DefectCauseCode.DefectCauseCode

{
   @ObjectModel.foreignKey.association: '_DefectCauseCodeGroup'
   key cast( qpct.codegruppe as vdm_qfecausegrp preserving type )  as DefectCauseCodeGroup,
   key cast( qpct.code       as vdm_qfecausecod preserving type )  as DefectCauseCode,
   @Semantics.language: true
   key qpct.sprache                                                as Language,
// key qpcd.version --> is always 1 so we could leave out


   @Semantics.text: true
   cast( qpct.kurztext as vdm_qfecausecod_text preserving type )   as DefectCauseCodeText,
   
   // Associations

   _DefectCauseCodeGroup,
   _DefectCauseCode
   
} where qpct.katalogart = '5' // Causes 

    and qpct.version    = '000001'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QPCT"
],
"ASSOCIATED":
[
"I_DEFECTCAUSECODE",
"I_DEFECTCAUSECODEGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More