I_DFS_MaintenanceOrderTechSts

@AbapCatalog.sqlViewName: 'IDFSORDERTECH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@EndUserText.label: 'Interface view for Tech Status of Order'
define view I_DFS_MaintenanceOrderTechSts
  as select from I_MaintenanceOrder as _MaintenanceOrder
  association [1..*] to I_StatusObjectActiveStatus  as _MaintOrderTechSts     on _MaintOrderTechSts.StatusObject = _MaintenanceOrder.DfsMaintOrderObjectNmbr
  association [1..1] to I_DFS_MaintFlightOrderBasic as _MaintFlightOrderBasic on _MaintenanceOrder.MaintenanceOrder = _MaintFlightOrderBasic.MaintenanceOrder
{
  _MaintenanceOrder.MaintenanceOrder,
  _MaintenanceOrder.MaintenanceNotification,
  _MaintenanceOrder.DfsMaintOrderObjectNmbr,
  _MaintenanceOrder.Equipment,
  _MaintenanceOrder._LocationAccountAssignment.FunctionalLocation,
  _MaintenanceOrder.MaintenanceOrderType,
  _MaintenanceOrder.DfsMaintSuperordinateEquipNmbr,
  _MaintenanceOrder.MaintenanceOrderDesc,
  _MaintenanceOrder.MaintOrderRoutingNumber,
  _MaintenanceOrder.MaintenanceProcessingPhase,
  _MaintenanceOrder.MaintenanceOrderCategory,
  _MaintOrderTechSts.StatusCode,
  _MaintOrderTechSts._StatusCode._StatusCodeText[ 1:Language = $session.system_language ].StatusShortName         as DfsMaintOrdTechStsShortName,
  _MaintOrderTechSts._StatusCode._StatusCodeText[ 1:Language = $session.system_language ].StatusName              as DfsMaintOrdTechStsLongName,
  _MaintOrderTechSts._StatusProfile.StatusProfile                                                                 as DfsMaintOrdTechStatusProfile,
  _MaintOrderTechSts._StatusProfile._StatusProfileText[ 1:Language = $session.system_language ].StatusProfileName as DfsMaintOrdTechStsPrflName,
  _MaintOrderTechSts
}
where
  _MaintFlightOrderBasic.MaintenanceOrder is null
//where

//       _MaintenanceOrder.MaintenanceOrderCategory = '30'

//  and(

//       MaintenanceProcessingPhase                 = '0'

//    or MaintenanceProcessingPhase                 = '1'

//    or MaintenanceProcessingPhase                 = '2'

//  )



/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DFS_MAINTFLIGHTORDERBASIC",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MAINTENANCEORDER",
"I_STATUSCODE",
"I_STATUSCODETEXT",
"I_STATUSOBJECTACTIVESTATUS",
"I_STATUSPROFILE",
"I_STATUSPROFILETEXT"
],
"ASSOCIATED":
[
"I_DFS_MAINTFLIGHTORDERBASIC",
"I_STATUSOBJECTACTIVESTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/