I_DFS_MaintStsBrdEquipment

@AbapCatalog.sqlViewName: 'ISTSBRDEQUIP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@EndUserText.label: 'Interface view for Status Board Equip'
define view I_DFS_MaintStsBrdEquipment
  as select from I_Equipment as _Equipment
  association [1..*] to I_StatusObjectActiveStatus    as _ActiveSysStatus         on  _ActiveSysStatus.StatusObject = _Equipment.MaintObjectInternalID
                                                                                  and _ActiveSysStatus.IsUserStatus = ''
                                                                                  and _ActiveSysStatus.StatusCode   = 'I0072'
  association [1..1] to I_DFS_MaintEquipFlxMtPlObjRIC as _MaintEquipFlxMtPlObjRIC on  $projection.Material = _MaintEquipFlxMtPlObjRIC.FlxMtPlObjVarModelProductID
  association [1..1] to I_DFS_MaintMasterEquipment    as _MaintMasterEquipment    on  $projection.Equipment = _MaintMasterEquipment.Equipment
  //Begin of changes

  association [1..*] to I_DFS_MaintItemDerivedData    as _MaintItemDerivedData    on  $projection.Equipment = _MaintItemDerivedData.Equipment
  //End of changes

{
  key  _Equipment.Equipment,
  key  cast( 'EAMS_EQUI' as eams_tec_obj_type_value )                                                                                                  as TechObjIsEquipOrFuncnlLoc,
       _Equipment.MaintObjectInternalID,
       _Equipment.EquipmentCategory,
       _Equipment.Material,
       _Equipment._Material._Text[ 1:Language = $session.system_language ].MaterialName,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._LocationAccountAssignment.FunctionalLocation                                      as DfsMaintFunctionalLocation,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._LocationAccountAssignment._FunctionalLocation._FunctionalLocationText[ 1:Language = $session.system_language ].FunctionalLocationName,
       ltrim(_Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ].SuperordinateEquipment,'0')                                                  as SuperordinateEquipment,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._SuperordinateEquipmentText[ 1:Language = $session.system_language ].EquipmentName as DfsMaintSuperordinateEquipName,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._WorkCenter._WorkCenterCostCenter.CostCenter,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._LocationAccountAssignment.CompanyCode,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._LocationAccountAssignment._CompanyCode.CompanyCodeName,
       _Equipment.CreatedByUser,
       _Equipment.CreationDate,
       ltrim( cast(  _Equipment.SerialNumber as abap.char(18) ), '0')                                                                                  as DfsMaintMaterialSerialNumber,
       _Equipment._EquipmentText[ 1:Language = $session.system_language ].EquipmentName,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._WorkCenter.WorkCenter,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._WorkCenter._Text[ 1:Language = $session.system_language ].WorkCenterText,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ]._WorkCenter.Plant,
       _Equipment._EquipmentTimeSeg[ ValidityEndDate = '99991231' ].MaintenancePlannerGroup,
       _Equipment._SerialNumberStockSegment.Batch,
       _Equipment._SerialNumberStockSegment.StorageLocation,
       _Equipment._SerialNumberStockSegment.Plant                                                                                                      as DfsMaintEquipmentPlant,
       _MaintMasterEquipment.DfsMaintIsForeignEquipment                                                                                                as DfsMaintIsForeignEquipment,
       _MaintEquipFlxMtPlObjRIC.FlxMtPlObjRIC,
       _MaintEquipFlxMtPlObjRIC.FlxMtPlObjRICDescription,
       _MaintEquipFlxMtPlObjRIC.FlxblMatlPlngObjectID,
       _MaintEquipFlxMtPlObjRIC.FlxblMatlPlngObjDescription,
       //Begin of changes

       _MaintItemDerivedData.UnitOfMeasureTechnicalName,
       _MaintItemDerivedData.MaintenanceCallNextPlannedDate,
       _MaintItemDerivedData.MeasuringPoint,
       _MaintItemDerivedData.DfsMaintMsmtRmngDaysValue,
       _MaintItemDerivedData.DfsMaintMsmtRmngDaysValueText,
       _MaintItemDerivedData.MeasurementReadingInEntryUoM,
       _MaintItemDerivedData.MsmtReadingInEntryFreeDfndTxt,
       _MaintItemDerivedData.DfsMaintMsmtRmngRdngsValue,
       _MaintItemDerivedData.DfsMaintMsmtRmngRdngsValueText,
       _MaintItemDerivedData.MaintCallNextPlndCntrRdng,
       _MaintItemDerivedData.MaintPlnCallCompltnCntrRdngVal,
       //End of changes

       cast( '' as abap.char(20) )                                                                                                                     as DfsMaintExplosionType,
       cast('' as abap.char(8) )                                                                                                                       as DfsMaintNumberOfNotifications,
       cast('' as abap.char(8) )                                                                                                                       as DfsMaintNumberOfWorkOrders,
       cast( '' as abap.char(20) )                                                                                                                     as DfsMaintFrcElmntOrgRoleText,
       cast( '' as abap.char(40))                                                                                                                      as DfsMaintEquipUserStsShortName,
       cast( '' as abap.char(40))                                                                                                                      as DfsMaintEquipSystStsShortName,
       cast( '' as abap.numc(8))                                                                                                                       as DfsMaintEquipmentUtilizerID,
       cast( '' as abap.char(40))                                                                                                                      as TechObjectWithLeadingZeros, 
        _MaintMasterEquipment.DfsMaintEquipmentType as DfsMaintEquipmentType  
}
where
  (
       _MaintMasterEquipment.DfsMaintEquipmentType is null
    or _MaintMasterEquipment.DfsMaintEquipmentType = 'D'
     or _MaintMasterEquipment.DfsMaintEquipmentType = 'S' //include site equipments

  )
  and  _Equipment.HasEquipmentData                 = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_DFS_MAINTEQUIPFLXMTPLOBJRIC",
"I_DFS_MAINTITEMDERIVEDDATA",
"I_DFS_MAINTMASTEREQUIPMENT",
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_EQUIPMENTTIMESEG",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONTEXT",
"I_LOCATIONACCOUNTASSIGNMENT",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_SERIALNUMBERSTOCKSEGMENT",
"I_WORKCENTER",
"I_WORKCENTERCOSTCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_DFS_MAINTEQUIPFLXMTPLOBJRIC",
"I_DFS_MAINTITEMDERIVEDDATA",
"I_DFS_MAINTMASTEREQUIPMENT",
"I_STATUSOBJECTACTIVESTATUS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/