I_DFS_AllwncPlanHierNodeBasic

@AbapCatalog.sqlViewName: 'IDFSALLWNCPLBHN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Plan Hier. Node with ref to Basic'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.dataCategory: #HIERARCHY

@VDM.viewType:#COMPOSITE
@VDM.lifecycle.contract.type:        #SAP_INTERNAL_API

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

define view I_DFS_AllwncPlanHierNodeBasic 
  as select from I_DFS_AllwncPlanBasic          as AllwncPlanBasic
    inner join   I_FrcElmntOrgWithAuthorization as _auth on AllwncPlanBasic.ForceElementOrgID = _auth.ForceElementOrgID
   association [0..1] to I_DFS_AllwncPlanHierNode as _Parent   on $projection.DfsAllwncPlanPreviousPlanUUID = _Parent.DfsAllwncPlanUUID


{
  key  DfsAllwncPlanUUID,
       DfsAllwncPlanID,
       DfsAllwncPlanDescription,
       DfsAllwncPlanValdtyStrtDate,
       DfsAllwncPlanValdtyEndDate,
       FlxblMatlPlngObjectUUID,
       FlxblMatlPlngObjectID,
       FlxblMatlPlngObjVariantUUID,
       FlxblMatlPlngObjVariantID,
       Product,
       DfsAllwncPlanBaseType,
       DfsAllwncPlanAllowedQuantity,
       DfsAllwncPlanQuantityUnit,
       FrcElmntOrgUsageType,
       DfsAllwncPlanMultiLevel,
       DfsAllwncPlanPreviousPlanUUID,

       DfsAllwncPlanComment,
       ForceElementOrgUUID,
       AllwncPlanBasic.ForceElementOrgID as ForceElementOrgID,
       //   ForceElementOrgID,

       DfsAllwncPlanIsCompleted,
       DfsAllwncPlanStatusObject,
       DfsAllwncPlanStatusCode,
       DfsAllwncPlanStatusProfile,


       /*-- Admin data --*/
       @Semantics.systemDateTime.createdAt: true
       DfsAllwncPlanCreationDateTime,
       @Semantics.user.createdBy: true
       DfsAllwncPlanCreatedByUser,
       @Semantics.systemDateTime.lastChangedAt: true
       DfsAllwncPlanChangeDateTime,
       @Semantics.user.lastChangedBy: true
       DfsAllwncPlanLastChgdByUser,
       case
            when
            (  DfsAllwncPlanPreviousPlanUUID  = hextobin( '00000000000000000000000000000000' ) ) then cast( 'X' as boole_d preserving type )
            else
            cast( ' ' as boole_d preserving type )
          end                            as DfsPlanIsRoot,

       /* Associations */
       _Parent

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DFS_ALLWNCPLANBASIC",
"I_FRCELMNTORGWITHAUTHORIZATION"
],
"ASSOCIATED":
[
"I_DFS_ALLWNCPLANHIERNODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/