I_DCBBaseLocationFilter

@AbapCatalog.sqlViewName: 'IDCBBASLOCFIL'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@Search.searchable: true
@EndUserText.label: 'Base Location filter'

@ObjectModel.usageType: {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}

define view I_DCBBaseLocationFilter
  as select distinct from /dmbe/c_Active_Location as _Location
{
      @Search.defaultSearchElement: false -- Hardcoded fields cannot be "searchable"
  key 'R'                                     as DealTransactionType, -- Intra-strategy locations
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key _Location.locationID                    as TSWLocationID,
      @Search.defaultSearchElement: false -- Hardcoded fields cannot be "searchable"
  key cast( '    ' as bukrs preserving type ) as DealInternalCompany,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      _Location.locationName                  as TSWLocationName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      _Location.searchTerm1                   as AddressSearchTerm1,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      _Location.searchTerm2                   as AddressSearchTerm2,
      @Search.defaultSearchElement: true
      _Location.locationType                  as TSWLocationType

}
union select from /dmbe/c_Active_Location as _Location
  inner join      I_OilPartnerRoles       as _PartnerRoles  on _PartnerRoles.LocationId = _Location.locationID
  inner join      /dmbe/i_Plant           as _Plant         on _PartnerRoles.Plant = _Plant.plant
  inner join      I_ValuationArea         as _ValuationArea on _ValuationArea.ValuationArea = _Plant.valuationArea
  inner join      /dmbe/i_Companycode     as _CompanyCode   on _CompanyCode.CompanyCode = _ValuationArea.CompanyCode

{

      @Search.defaultSearchElement: false -- Hardcoded fields cannot be "searchable"
  key 'H'                      as DealTransactionType, -- Inter-strategy locations
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key _Location.locationID     as TSWLocationID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key _CompanyCode.CompanyCode as DealInternalCompany,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      _Location.locationName   as TSWLocationName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      _Location.searchTerm1    as AddressSearchTerm1,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      _Location.searchTerm2    as AddressSearchTerm2,
      @Search.defaultSearchElement: true
      _Location.locationType   as TSWLocationType

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/DMBE/C_ACTIVE_LOCATION",
"/DMBE/I_COMPANYCODE",
"/DMBE/I_PLANT",
"I_OILPARTNERROLES",
"I_VALUATIONAREA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/