I_CustomerMaterial

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #M 
@ObjectModel.representativeKey: 'Customer'
@EndUserText.label: 'Customer Material Information'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: [ 'Customer' ]
@AbapCatalog.sqlViewName: 'ISDCUSTMATLINFO'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@Analytics: { 
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true
    }
}
@ObjectModel.modelingPattern:           #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities:  [  #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #ANALYTICAL_DIMENSION,
                                        #EXTRACTION_DATA_SOURCE  ]        
@VDM.lifecycle.status: #DEPRECATED                                                      
@VDM.lifecycle.successor: 'I_CUSTOMERMATERIAL_2'               
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_CustomerMaterial 
  as select from  knmt
association [0..1] to I_SalesOrganization          as _SalesOrganization             on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
association [0..1] to I_DistributionChannel        as _DistributionChannel           on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
association [0..1] to I_Customer                   as _Customer                      on  $projection.Customer = _Customer.Customer
association [0..1] to I_Material                   as _Material                      on  $projection.Material = _Material.Material
association [0..1] to I_Product                    as _Product                       on  $projection.Product = _Product.Product
association [0..1] to I_Plant                      as _Plant                         on  $projection.Plant = _Plant.Plant
association [0..1] to I_DeliveryPriority           as _DeliveryPriority              on  $projection.DeliveryPriority = _DeliveryPriority.DeliveryPriority
association [0..1] to I_UnitOfMeasure              as _BaseUnit                      on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
association [0..1] to I_PartialDeliveryItem        as _PartialDeliveryIsAllowed      on  $projection.PartialDeliveryIsAllowed = _PartialDeliveryIsAllowed.PartialDeliveryIsAllowed
association [0..1] to I_CustomerMaterialItemUsage  as _CustomerMaterialItemUsage     on  $projection.CustomerMaterialItemUsage = _CustomerMaterialItemUsage.CustomerMaterialItemUsage
association [0..*] to I_AdditionalCustomerMaterial as _AdditionalCustomerMaterial    
    on  $projection.SalesOrganization = _AdditionalCustomerMaterial.SalesOrganization 
    and $projection.DistributionChannel = _AdditionalCustomerMaterial.DistributionChannel
    and $projection.Customer = _AdditionalCustomerMaterial.Customer
    and $projection.Material = _AdditionalCustomerMaterial.Material
//Extensibility

association [0..1] to E_CustomerMaterial  as _Extension  on  $projection.Material = _Extension.Material
                                                         and $projection.Customer = _Extension.Customer
                                                         and $projection.SalesOrganization = _Extension.SalesOrganization
                                                         and $projection.DistributionChannel = _Extension.DistributionChannel
    

{
     @ObjectModel.foreignKey.association: '_SalesOrganization'
 key vkorg     as SalesOrganization,
     @ObjectModel.foreignKey.association: '_DistributionChannel'
 key vtweg     as DistributionChannel,
     @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Customer_VH', element: 'Customer' } } ]
 key kunnr     as Customer,
     @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
     @ObjectModel.foreignKey.association: '_Material'
 key matnr     as Material,
     @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductStdVH', element: 'Product' } } ]
     @ObjectModel.foreignKey.association: '_Product'
     cast(matnr as productnumber preserving type ) as Product,
     sortl     as SortField,
     sortl     as ETag,

     // Customer Material

     kdmat     as MaterialByCustomer,    
     @Semantics.text: true
     postx     as MaterialDescriptionByCustomer,
     
     // Shipping

     @ObjectModel.foreignKey.association: '_Plant'
     werks     as Plant,
     @ObjectModel.foreignKey.association: '_DeliveryPriority'
     lprio     as DeliveryPriority,
     @Semantics.quantity.unitOfMeasure: 'BaseUnit'
     minlf     as MinDeliveryQtyInBaseUnit,
     @Semantics.unitOfMeasure: true
     @ObjectModel.foreignKey.association: '_BaseUnit'
     meins     as BaseUnit,
     
     // Partial Delivery

     @ObjectModel.foreignKey.association: '_PartialDeliveryIsAllowed'
     kztlf     as PartialDeliveryIsAllowed,
     antlf     as MaxNmbrOfPartialDelivery,
     untto     as UnderdelivTolrtdLmtRatioInPct,
     uebto     as OverdelivTolrtdLmtRatioInPct,
     uebtk     as UnlimitedOverdeliveryIsAllowed,
     
     // Control Data

     @ObjectModel.foreignKey.association: '_CustomerMaterialItemUsage'
     vwpos     as CustomerMaterialItemUsage,
     
     // Units of Measure

     vrkme_t   as SalesUnit,
     umvkn_t   as SalesQtyToBaseQtyDnmntr,
     umvkz_t   as SalesQtyToBaseQtyNmrtr,

     _SalesOrganization,
     _DistributionChannel,
     _Customer,
     _Material,
     _Product,
     _Plant,
     _DeliveryPriority,
     _BaseUnit,
     _PartialDeliveryIsAllowed,
     _CustomerMaterialItemUsage,
     _AdditionalCustomerMaterial
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"KNMT"
],
"ASSOCIATED":
[
"E_CUSTOMERMATERIAL",
"I_ADDITIONALCUSTOMERMATERIAL",
"I_CUSTOMER",
"I_CUSTOMERMATERIALITEMUSAGE",
"I_DELIVERYPRIORITY",
"I_DISTRIBUTIONCHANNEL",
"I_MATERIAL",
"I_PARTIALDELIVERYITEM",
"I_PLANT",
"I_PRODUCT",
"I_SALESORGANIZATION",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/