I_CustomerContactVH

DDL: I_CUSTOMERCONTACTVH Type: view COMPOSITE

Customer Contact Value Help

I_CustomerContactVH is a Composite CDS View that provides data about "Customer Contact Value Help" in SAP S/4HANA. It reads from 2 data sources (I_BusinessPartnerCustomer, I_CustomerContact) and exposes 13 fields with key field CustomerContact. It has 2 associations to related views.

2 data source(s) 13 fields

Data Sources (2)

SourceAliasJoin Type
I_BusinessPartnerCustomer I_BusinessPartnerCustomer from
I_CustomerContact I_CustomerContact inner

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_Customer _Customer $projection.Customer = _Customer.Customer
[0..1] I_Customer_VH _CustomerVH $projection.Customer = _CustomerVH.Customer

Annotations (17)

NameValueLevelField
AbapCatalog.sqlViewName ICUSTCONTVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
EndUserText.label Customer Contact Value Help view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey CustomerContact view
Metadata.ignorePropagatedAnnotations true view
Search.searchable true view
Consumption.ranked true view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY CustomerContact CustomerContact
Customer Customer
BusinessPartnerName BusinessPartnerName
InternationalPhoneNumber InternationalPhoneNumber
InternationalMobilePhoneNumber InternationalMobilePhoneNumber
InternationalFaxNumber InternationalFaxNumber
EmailAddress EmailAddress
ContactPersonDepartment ContactPersonDepartment
ContactPersonFunction ContactPersonFunction
_ContactPersonDepartment _ContactPersonDepartment
_ContactPersonFunction _ContactPersonFunction
_Customer _Customer
_CustomerVH _CustomerVH 
@AbapCatalog: { sqlViewName: 'ICUSTCONTVH',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Customer Contact Value Help' }
@VDM: { viewType:  #COMPOSITE,
        lifecycle: { contract: { type: #PUBLIC_LOCAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #X,
                             sizeCategory: #S,
                             dataClass: #TRANSACTIONAL },
                dataCategory: #VALUE_HELP,
                semanticKey: [ 'CustomerContact' ],
                representativeKey: 'CustomerContact' }
@Metadata: { ignorePropagatedAnnotations: true }
@Search: { searchable: true }
@Consumption: { ranked: true }

define view I_CustomerContactVH
  as select from I_BusinessPartnerCustomer
    inner join   I_CustomerContact on I_BusinessPartnerCustomer.BusinessPartner = I_CustomerContact.BusinessPartnerCompany

  // VDM Associations

  // Customer

  association [0..1] to I_Customer    as _Customer   on $projection.Customer = _Customer.Customer

  // Customer Value Help

  association [0..1] to I_Customer_VH as _CustomerVH on $projection.Customer = _CustomerVH.Customer

{
      // VDM Fields

      @UI: { lineItem: [ { position: 10,
                           importance: #HIGH } ] }
  key CustomerContact,

      @Consumption: { valueHelpDefinition: [ { association: '_CustomerVH' } ] }
      Customer,

      @UI: { lineItem: [ { position: 20,
                                importance: #HIGH } ] }
      @EndUserText: { label:     'Business Partner Name',
                      quickInfo: 'Business Partner Name' }
      BusinessPartnerName,

      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @UI: { lineItem: [ { position: 30,
                           importance: #HIGH } ] }
      InternationalPhoneNumber,

      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @UI: { lineItem: [ { position: 40,
                           importance: #HIGH } ] }
      @EndUserText: { label:     'Mobile Phone Number',
                      quickInfo: 'Mobile Phone Number' }
      InternationalMobilePhoneNumber,

      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @UI: { lineItem: [ { position: 50,
                           importance: #HIGH } ] }
      InternationalFaxNumber,

      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @UI: { lineItem: [ { position: 60,
                           importance: #HIGH } ] }
      EmailAddress,

      @UI: { lineItem: [ { position: 70,
                           importance: #MEDIUM } ] }
      ContactPersonDepartment,

      @UI: { lineItem: [ { position: 80,
                           importance: #MEDIUM } ] }
      ContactPersonFunction,

      // Exposed Associations

      _ContactPersonDepartment,
      _ContactPersonFunction,
      _Customer,
      _CustomerVH

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERCUSTOMER",
"I_CUSTOMERCONTACT"
],
"ASSOCIATED":
[
"I_CONTACTPERSONDEPARTMENT",
"I_CONTACTPERSONFUNCTION",
"I_CUSTOMER",
"I_CUSTOMER_VH"
],
"BASE":
[
"I_CUSTOMERCONTACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More