I_CustomCDSViewRework_KeyUpper

// ------------------------------------------------------------------------------------------------------------------------------------

// Note

// In case of changes, these must also be made in  => I_CustomCDSViewRework (used in our value helps of data sources)

// Only the key is different. In our Value Helps we need the UpperCase name, otherwise the CamelCase name

// ------------------------------------------------------------------------------------------------------------------------------------


@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Custom CDS View Rework - upper name'

define view entity I_CustomCDSViewRework_KeyUpper
  
  as select from atov_bom_rework_demand
  
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/ 
  association [0..1] to I_CCV_REWORK_TASK_PRIORITY_VH as _TaskPriority on _TaskPriority.CodeInt = atov_bom_rework_demand.Highest_Priority
  association [0..1] to I_CCV_REWORK_TASK_CATEGORY_VH as _TaskCategory on _TaskCategory.Code    = atov_bom_rework_demand.Rework_Category
{

  key object_name                                                          as EntityName,

      item_id                                                              as ItemId,
      item_type                                                            as ItemType,
      @EndUserText.label: 'Rework'
      @Consumption.filter : { selectionType: #SINGLE,  multipleSelections : false}
      cast( Rework as aps_ccv_rework_ind preserving type )                 as ReworkIndicator,
      @ObjectModel.text.element: ['HighestPriorityText']
      cast( Highest_Priority  as aps_ccv_r_task_priority preserving type ) as HighestPriority,
      Highest_Priority_Sort_Order                                          as HighestPrioritySortOrder,
      @EndUserText.label: 'Task Priority'
      @ObjectModel: { foreignKey.association: '_TaskPriority', readOnly: true }
      @Consumption.valueHelpDefinition: [{entity: {name: 'I_CCV_REWORK_TASK_PRIORITY_VH', element: 'Description' } }]      
      _TaskPriority.Description                                            as HighestPriorityText,
      Priority_Text                                                        as PriorityText,
      cast( Rework_Category as aps_ccv_r_task_category preserving type )   as Category,
      @Consumption.valueHelpDefinition: [{entity: {name: 'I_CCV_REWORK_TASK_CATEGORY_VH', element: 'Description' } }]      
      Rework_Category_Text                                                 as CategoryText,

      _TaskPriority,
      _TaskCategory

}
where
  pgmid = 'R3TR'  and
  object = 'DDLS' and
  ( item_type = 'CKE'   or 
    item_type = 'SCBO'  or 
    item_type = 'SCCL' 
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ATOV_BOM_REWORK_DEMAND",
"I_CCV_REWORK_TASK_PRIORITY_VH"
],
"ASSOCIATED":
[
"I_CCV_REWORK_TASK_CATEGORY_VH",
"I_CCV_REWORK_TASK_PRIORITY_VH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/