I_CustUnivHierNodeText

@AbapCatalog: {
  sqlViewName: 'ICUSTUHFNDT',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@EndUserText.label: 'Customer Hierarchy Node - Text'
@Analytics: {
  internalName: #LOCAL
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  representativeKey: 'HierarchyNode',
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #XL
  },
  dataCategory: #TEXT
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #LANGUAGE_DEPENDENT_TEXT
]

define view I_CustUnivHierNodeText 
  as select from hrrp_nodet     as nodet
    inner join   hrrp_directory as dir on  dir.hryid    = nodet.hryid
                                       and dir.hryvalto = nodet.hryvalto
                                       and dir.hryver   = nodet.hryver 
  //[1..*] as they are temporal assoc

  association [1..*] to I_CustUnivHierarchyBase     as _CustomerHierarchy     on  $projection.CustomerUniversalHierarchy = _CustomerHierarchy.CustomerUniversalHierarchy

  association [1..*] to I_CustUnivHierarchyNodeBase as _CustomerHierarchyNode on  $projection.CustomerUniversalHierarchy = _CustomerHierarchyNode.CustomerUniversalHierarchy
                                                                              and $projection.HierarchyNode     = _CustomerHierarchyNode.HierarchyNode

{

      @Semantics.language: true
  key spras                                                                     as Language,
      @ObjectModel.foreignKey.association: '_CustomerHierarchy'
  key dir.hrysid                                                                as CustomerUniversalHierarchy,
      @ObjectModel.foreignKey.association: '_CustomerHierarchyNode'
  key nodet.hrynode                                                             as HierarchyNode,
      @Semantics.businessDate.to: true
  key cast(nodet.hryvalto as custhierarchyvalidityenddate preserving type )     as CustHierarchyValidityEndDate,
      @Semantics.businessDate.from: true
      cast(nodet.hryvalfrom as custhierarchyvaliditystartdate preserving type ) as CustHierarchyValidityStartDate,
      @Semantics.text: true
      cast(nodetxt as cust_hier_node_value_text )                               as CustUnivHierarchyNodeText,

      _CustomerHierarchy,
      _CustomerHierarchyNode // Make association public

}
where
     dir.hrytyp = 'CH02'
  or dir.hrytyp = 'CH01'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIRECTORY",
"HRRP_NODET"
],
"ASSOCIATED":
[
"I_CUSTUNIVHIERARCHYBASE",
"I_CUSTUNIVHIERARCHYNODEBASE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/