I_CreditorFinancialData

@EndUserText.label: 'Creditor Financial Data'
@AbapCatalog.sqlViewName: 'IFICREFIDAT'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'Creditor'
@Analytics: { dataCategory: #DIMENSION }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@Metadata.allowExtensions:true
@ObjectModel.usageType.serviceQuality:#C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:#MIXED

define view I_CreditorFinancialData
  as select from lfb1
  //left outer join t001s on  lfb1.bukrs = t001s.bukrs and

  //                          lfb1.busab = t001s.busab


  association [0..1] to I_Supplier        as _Supplier        on  $projection.Creditor = _Supplier.Supplier
  association [0..1] to I_CompanyCode     as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_AccountingClerk as _AccountingClerk on  $projection.CompanyCode     = _AccountingClerk.CompanyCode
                                                              and $projection.AccountingClerk = _AccountingClerk.AccountingClerk

{

      @ObjectModel.foreignKey.association: '_Supplier'
  key cast(lfb1.lifnr as fis_lifnr)    as Creditor,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key lfb1.bukrs                       as CompanyCode,
      cast( lfb1.akont as farp_akont)  as ReconciliationAccount,
      lfb1.begru                       as AuthorizationGroup,
      cast( lfb1.vzskz as farp_vzskz)  as InterestCalculationCode,
      cast(lfb1.zahls as dzahls)       as PaymentBlockingReason,
      cast( lfb1.kverm as farp_kverm)  as Note,
      @ObjectModel.foreignKey.association: '_AccountingClerk'
      cast( lfb1.busab as farp_busab)  as AccountingClerk,
      //t001s.sname as AccountingClerkName, // Can be retrieved via the association _AccountingClerk if needed

      //cast(lfb1.lnrze as FARP_LNRZE) as HeadOfficeAccount,

      cast( lfb1.lnrzb as farp_lnrzb)  as AlternativePayee,
      cast( lfb1.zindt as farp_dzindt) as InterestCalculationDate,
      cast( lfb1.zinrt as farp_dzinrt) as IntrstCalcFrequencyInMonths,
      cast( lfb1.togru as farp_togru)  as APARToleranceGroup,
      cast( lfb1.hbkid as farp_hbkid)  as HouseBank,
      cast( lfb1.xpore as farp_xpore)  as ItemIsToBePaidSeparately,
      cast( lfb1.xedip as farp_xedip)  as PaymentIsToBeSentByEDI,
      _CompanyCode,
      _Supplier,
      _AccountingClerk

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"LFB1"
],
"ASSOCIATED":
[
"I_ACCOUNTINGCLERK",
"I_COMPANYCODE",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/