I_CreditManagementBPRating

@AbapCatalog.sqlViewName: 'ICRBPRATING'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
//@VDM.private: false

@Metadata.ignorePropagatedAnnotations:true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Credit Management BP Rating'
@ObjectModel.representativeKey: 'BusinessPartnerRatingProcedure'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@AccessControl.personalData.blocking: #REQUIRED
define view I_CreditManagementBPRating
  as select from bp1012
    inner join   I_CreditManagementBP on I_CreditManagementBP.BusinessPartner = bp1012.partner
  association [0..1] to I_BusinessPartner        as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_CreditManagementRating as _Rating          on  $projection.BusinessPartnerRatingProcedure = _Rating.BusinessPartnerRatingProcedure
                                                                     and $projection.BusinessPartnerRating          = _Rating.BusinessPartnerRating
{
      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key bp1012.partner                                                           as BusinessPartner,
  key bp1012.grade_method                                                      as BusinessPartnerRatingProcedure,
      _BusinessPartner.AuthorizationGroup,
      date_from                                                                as BPRatingValidityStartDate,
      date_to                                                                  as BPRatingValidityEndDate,
      flg_permit                                                               as BusinessPartnerRatingIsAllowed,
      bp1012.grade                                                             as BusinessPartnerRating,
      _Rating.BusinessPartnerRanking                                           as BusinessPartnerRanking,
      _Rating.BusinessPartnerRatingName                                        as BusinessPartnerRatingName,
      _Rating._Text[1:Language = $session.system_language].BPRatingDescription as BPRatingDescription,
      _BusinessPartner,
      _Rating
}
where
  date_to >= $session.system_date
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_CREDITMANAGEMENTBP",
"I_CREDITMANAGEMENTRATING",
"I_CREDITMANAGEMENTRATINGTEXT",
"BP1012"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CREDITMANAGEMENTRATING"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/