I_CostCenterLabelTP

@AbapCatalog.sqlViewName: 'IFICOSTCNTRLBLTP'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

// Draft Related Annotations

@ObjectModel.writeDraftPersistence: 'CSKT_DRAFT'
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: [ 'Language', 'ControllingArea', 'CostCenter', 'ValidityEndDate' ]

@ObjectModel.usageType.dataClass: #ORGANIZATIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Languages'

define view I_CostCenterLabelTP
  as select from I_CostCenterText
  
    association [1..1] to I_CostCenterTP       as _CostCenter         on  $projection.ControllingArea    = _CostCenter.ControllingArea
                                                                        and $projection.CostCenter       = _CostCenter.CostCenter
                                                                        and $projection.ValidityEndDate  = _CostCenter.ValidityEndDate
    
    association[0..1] to I_Language as _Language on $projection.LanguageForEdit = _Language.Language
{

  key Language,
  
  key ControllingArea,
  
  key CostCenter,

  key ValidityEndDate,
  
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Language as LanguageForEdit,

      CostCenterName,

      cast( CostCenterDescription as fis_cc_kostl_ltext preserving type ) as CostCenterDescription,
      
      @ObjectModel.readOnly: true
      cast ( '' as fco_long_text_indicator ) as UxFcCostCenterDescription,
      
      @ObjectModel.readOnly: true    
      _Language.LanguageISOCode,
      
      @ObjectModel.readOnly: true    
      _Language._Text[1:Language=$session.system_language].LanguageName,
      
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _CostCenter,
      
      _Language

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COSTCENTERTEXT",
"I_LANGUAGE",
"I_LANGUAGETEXT"
],
"ASSOCIATED":
[
"I_COSTCENTERTP",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/