I_CostCenterCategory

@EndUserText.label: 'Cost Center Category'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFICOSTCTRCAT'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'CostCenterCategory'
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@AbapCatalog.buffering: {type: #GENERIC, numberOfKeyFields: 1, status: #ACTIVE}
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.compiler.compareFilter: true
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.sapObjectNodeType.name: 'CostCenterCategory'

define view I_CostCenterCategory
  as select from tka05
  association [0..*] to I_CostCenterCategoryText as _Text           on $projection.CostCenterCategory = _Text.CostCenterCategory
  association [0..1] to I_FunctionalArea         as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
{
      @ObjectModel.text.association: '_Text'
  key kosar                    as CostCenterCategory,
      bkzkp                    as IsBlkdForPrimaryCostsPosting,
      bkzks                    as IsBlkdForSecondaryCostsPosting,
      bkzer                    as IsBlockedForRevenuePosting,
      bkzob                    as IsBlockedForCommitmentPosting,
      pkzkp                    as IsBlockedForPlanPrimaryCosts,
      cast(pkzks as fis_pkzks) as IsBlockedForPlanSecondaryCosts,
      cast(pkzer as fis_pkzer) as IsBlockedForPlanRevenues,
      cast(vmeth as fis_vmeth) as CostCenterAllocationMethod,
      mgefl                    as ConsumptionQtyIsRecorded,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      func_area                as FunctionalArea,

      _Text,
      _FunctionalArea

};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TKA05"
],
"ASSOCIATED":
[
"I_COSTCENTERCATEGORYTEXT",
"I_FUNCTIONALAREA"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/