I_ConcnUnitOfMsmtValueHelp

--Label of view
@EndUserText.label: 'Unit of Measurement for Concentration Values in Composition'

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'ICONCUMOVH',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true,
  preserveKey: true

}

--Access Control: Authorizations Checks
@AccessControl:
{
  authorizationCheck: #NOT_REQUIRED
}
             

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE


@ObjectModel:
{
  --for value help
  dataCategory: #VALUE_HELP,
  resultSet.sizeCategory: #XS,
  usageType:
  {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #B
  }
}

@Search.searchable: true

define view I_ConcnUnitOfMsmtValueHelp
  as select from I_UnitOfMeasure
{
      --Unit of measurement
      @Search:
      {
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      @ObjectModel.text.element: ['UnitOfMeasureTechnicalName']
  key UnitOfMeasure,

      --Short description (3 chars) of unit of measurement
      @Search:
      {
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      UnitOfMeasure_E,

      --Short description (6 chars) of unit of measurement
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.9,
        ranking: #HIGH
      }
      _Text[1: Language = $session.system_language].UnitOfMeasureTechnicalName,

      --Long description
      @Search:
      {
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      _Text[1: Language = $session.system_language].UnitOfMeasureLongName,

      /*Association*/
      _Text
}
where
     UnitOfMeasure = '%'
  or UnitOfMeasure = 'PPM'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT"
],
"ASSOCIATED":
[
"I_UNITOFMEASURETEXT"
],
"BASE":
[
"I_UNITOFMEASURE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/