I_CommodityOrderLeg

@AbapCatalog.sqlViewName                : 'ICOMMODITYORDLEG'
@AbapCatalog.compiler.compareFilter     : true
@AbapCatalog.preserveKey                : true
@AccessControl.authorizationCheck       : #CHECK
@AccessControl.personalData.blocking    : #REQUIRED
@VDM.viewType                           : #COMPOSITE
@Search.searchable                      : false
@EndUserText.label                      : 'Commodity Derivative Order Leg Details'

@ClientHandling: {
   type         : #CLIENT_DEPENDENT,
   algorithm    : #SESSION_VARIABLE
}

---- Object Model for Commodity Order Request Leg
@ObjectModel.usageType: {
        serviceQuality : #D,
        sizeCategory   : #L,
        dataClass      : #TRANSACTIONAL   
}

define view I_CommodityOrderLeg
  as select from    I_CmmdtyOrderReqLeg       as Leg

  -- To get text for Commodity Order Request Flow Type
    left outer join I_CmmdtyDrvtvFlowTypeText as CmmdtyDrvtvFlowTypeText on Leg.CmmdtyOrderRequestFlowType = CmmdtyDrvtvFlowTypeText.CmmdtyOrderRequestFlowType

  --To get Future Details
    left outer join I_CmmdtyOrderFutureIDVH   as FutureId                on  Leg.CommodityDerivativeFuture = FutureId.CmmdtyOrderFillFutureID
                                                                         and Leg.MaturityKeyDate           = FutureId.MaturityKeyDate
{

  key    Leg.CmmdtyOrderReqLegUUID                                                  as CmmdtyOrderReqLegUUID,
         Leg.CommodityOrderRequestUUID                                              as CommodityOrderRequestUUID,

         -------------------------Commodity Order Request Leg Information----------------------------------
         Leg.CmmdtyOrderReqLegCategory                                              as CmmdtyOrderReqLegCategory,
         Leg.CmmdtyOrderRequestFlowType                                             as CmmdtyOrderRequestFlowType,
         CmmdtyDrvtvFlowTypeText.CmmdtyDerivativeFlowTypeText                       as CmmdtyDerivativeFlowTypeText,
         Leg.CmmdtyOrdRequestQuantityInLot                                          as CmmdtyOrdRequestQuantityInLot,
         Leg.CmmdtyDerivativeQuantityPerLot                                         as CmmdtyDerivativeQuantityPerLot,
         Leg.CmmdtyDrvtvQuantityUnitPerLot                                          as CmmdtyDrvtvQuantityUnitPerLot,
         Leg.CmmdtyDerivativeCurrencyPerLot                                         as CmmdtyDerivativeCurrencyPerLot,

         -------------------------Future Information-------------------------------------------------------
         Leg.CommodityDerivativeFuture                                              as CommodityDerivativeFuture,
         FutureId.CmmdtyOrderFillFutureName                                         as CommodityDerivativeFutureName,
         
         cast(FutureId.DerivativeContrSpecification
           as cmmfdor_derivativecontractspec preserving type )                      as DerivativeContrSpecification,
         FutureId.DerivativeContrSpecName                                           as DerivativeContrSpecName,
           
         FutureId.MarketIdentifierCode                                              as MarketIdentifierCode,
         FutureId.MarketIdentifierCodeName                                          as MarketIdentifierCodeName,
         
         cast(FutureId.Commodity
           as cmmfdor_exchangecommodity preserving type )                           as Commodity,
         FutureId.CommodityName                                                     as CommodityName,
           
         Leg.MaturityKeyDate                                                        as MaturityKeyDate,

         -------------------------Administrative Data------------------------------------------------------
         Leg.CreatedByUser                                                          as CreatedByUser,
         Leg.CreationDateTime                                                       as CreationDateTime,
         Leg.LastChangedByUser                                                      as LastChangedByUser,
         Leg.LastChangeDateTime                                                     as LastChangeDateTime
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMMDTYDRVTVFLOWTYPETEXT",
"I_CMMDTYORDERFUTUREIDVH",
"I_CMMDTYORDERREQLEG"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/