I_CollsInvoiceRelatedResubmsn

@AbapCatalog: { sqlViewName: 'ICOLLSINVRELRSM',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK }
@EndUserText.label: 'Resubmission Related to Invoice'
@VDM: { viewType: #COMPOSITE,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #A,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                semanticKey: [ 'ResubmissionUUID' ] }

define root view I_CollsInvoiceRelatedResubmsn
  as select from I_CollsInvoiceRelatedObject

  // VDM Associations

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _CreatedByContactCard on $projection.createdbyuser = _CreatedByContactCard.ContactCardID

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ChangedByContactCard on $projection.changedby = _ChangedByContactCard.ContactCardID

{

      // VDM Fields

  key LogicalSystem,
  key ObjectType,
  key ObjectKey,
  key RelationToLinkedObject,
  key CaseUniqueID as ResubmissionUUID,
      ObjectClassification,
      ObjectIsConfirmed,
      ObjectIsVoided,
      CompanyCode,
      AccountingDocument,
      FiscalYear,
      AccountingDocumentItem,
      CaseID,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      _CollectionsResubmission.CreatedByUser,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      _CollectionsResubmission.ChangedBy,

      _CollectionsResubmission.ResubmissionStatus,

      _CollectionsResubmission.ResubmissionDueDate,

      _CollectionsResubmission.CreationDateTime,

      // Exposed Associations

      _CaseAttribute,
      _CollectionsResubmission,
      _CreatedByContactCard,
      _ChangedByContactCard

}

where
      RelationToLinkedObject =  'R1'
  and ObjectType             =  'BSEG'
  and ObjectIsVoided         <> 'X'
  and _CollectionsResubmission.ResubmissionDueDate != '99991231'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COLLECTIONSRESUBMISSION",
"I_COLLSINVOICERELATEDOBJECT"
],
"ASSOCIATED":
[
"I_CASEATTRIBUTE",
"I_COLLECTIONSRESUBMISSION",
"R_RBLSMGMTUSERCONTACTCARD"
],
"BASE":
[
"I_COLLSINVOICERELATEDOBJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/