I_CollsInvcPaytDelayPrediction

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Payment Delay Prediction' }
@VDM: { viewType:  #BASIC,
        lifecycle: { contract: { type: #PUBLIC_LOCAL_API } } }
@Analytics: { technicalName: 'ICOLLINVPAYDELPRD' }
@ObjectModel: { usageType:         { serviceQuality: #A,
                                     sizeCategory:   #XL,
                                     dataClass:      #TRANSACTIONAL },
                semanticKey: [ 'CompanyCode',
                               'FiscalYear',
                               'AccountingDocument',
                               'AccountingDocumentItem' ],
                representativeKey: 'AccountingDocumentItem' }

define root view entity I_CollsInvcPaytDelayPrediction
  as select from udm_coll_pay_prd

  // VDM Associations

  // Company Code

  association [0..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode

  // Accounting Document Item

  association [0..1] to I_OperationalAcctgDocItem    as _OperationalAcctgDocItem    on  $projection.CompanyCode            = _OperationalAcctgDocItem.CompanyCode
                                                                                    and $projection.AccountingDocument     = _OperationalAcctgDocItem.AccountingDocument
                                                                                    and $projection.FiscalYear             = _OperationalAcctgDocItem.FiscalYear
                                                                                    and $projection.AccountingDocumentItem = _OperationalAcctgDocItem.AccountingDocumentItem

  // Risk of late payment

  association [0..1] to I_CollectionsLatePaymentRisk as _CollectionsLatePaymentRisk on  $projection.LatePaymentRisk = _CollectionsLatePaymentRisk.LatePaymentRisk

{
      // VDM Fields

  key bukrs                                                                            as CompanyCode,
  key belnr                                                                            as AccountingDocument,
  key gjahr                                                                            as FiscalYear,
  key buzei                                                                            as AccountingDocumentItem,
      prediction_score                                                                 as ClearingDelayInDaysScoreValue,
      ( FLTP_TO_DEC( prediction_probability as udm_coll_prob_of_late_payment ) * 100 ) as ClrgDlyInDaysProbabilityValue,

      cast( case when prediction_decision = '1'
              then 'X'
            else ' ' end as udm_coll_clrng_delay_ovr_thres preserving type )           as ClrgDelayInDaysIsOverThreshold,
      reason_1_field                                                                   as ClrgDlyInDaysInflncgParam1,
      cast ( reason_1_quality as udm_coll_pred_reas_1_quality )                        as ClrgDlyInflncgParam1QltyVal,
      reason_2_field                                                                   as ClrgDlyInDaysInflncgParam2,
      cast (  reason_2_quality as udm_coll_pred_reas_2_quality )                       as ClrgDlyInflncgParam2QltyVal,
      reason_3_field                                                                   as ClrgDlyInDaysInflncgParam3,
      cast( reason_3_quality as udm_coll_pred_reas_3_quality )                         as ClrgDlyInflncgParam3QltyVal,
      late_payment_risk                                                                as LatePaymentRisk,

      // Exposed Associations

      _CompanyCode,
      _OperationalAcctgDocItem,
      _CollectionsLatePaymentRisk

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UDM_COLL_PAY_PRD"
],
"ASSOCIATED":
[
"I_COLLECTIONSLATEPAYMENTRISK",
"I_COMPANYCODE",
"I_OPERATIONALACCTGDOCITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/