I_CollectionsCustomerContactVH

@AbapCatalog: { sqlViewName: 'ICOLLSCSTCNTVH',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Collections Customer Contact VH' }
@VDM: { viewType: #COMPOSITE }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory: #S,
                             dataClass: #TRANSACTIONAL },
                dataCategory: #VALUE_HELP,
                representativeKey: 'CustomerContact' }
@Search: { searchable: true }
@Consumption: { ranked: true }

define view I_CollectionsCustomerContactVH
  as select from I_CustomerContact

  // VDM Associations

  // Relationships

  association [0..1] to I_BPRelationship    as _BPRelationship           on  $projection.BusinessPartnerCompany   = _BPRelationship.BusinessPartner1
                                                                         and $projection.BusinessPartnerPerson    = _BPRelationship.BusinessPartner2
                                                                         and _BPRelationship.RelationshipCategory = 'UDM001'

  // Business Partner Company Value Help

  association [0..1] to I_BusinessPartnerVH as _BusinessPartnerCompanyVH on  $projection.BusinessPartnerCompany = _BusinessPartnerCompanyVH.BusinessPartner

  // Business Partner Person Value Help

  association [0..1] to I_BusinessPartnerVH as _BusinessPartnerPersonVH  on  $projection.BusinessPartnerPerson = _BusinessPartnerPersonVH.BusinessPartner

{

      // VDM Fields

      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #HIGH }
      @UI: { hidden: true }
  key CustomerContact,

      @UI: { hidden: true }
      RelationshipNumber,

      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #LOW }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER } },
                      valueHelpDefinition: [ { association: '_BusinessPartnerCompanyVH' } ] }
      BusinessPartnerCompany,

      @UI: { lineItem: { position: 20 } }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } },
                      valueHelpDefinition: [ { association: '_BusinessPartnerPersonVH' } ] }
      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #LOW }
      @ObjectModel: { text: { element: [ 'BusinessPartnerName' ] } }
      @EndUserText: { label:     'Contact Person',
                      quickInfo: 'Contact Person for Customer' }
      BusinessPartnerPerson,

      @UI: { lineItem: { position: 30 } }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      @Semantics: { text: true }
      @EndUserText: { label:     'Contact Person Name',
                      quickInfo: 'Name of Contact Person' }
      BusinessPartnerName,

      @UI: { hidden: true }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #LOW }
      FirstName,

      @UI: { hidden: true }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      @Search: { defaultSearchElement: true,
                 fuzzinessThreshold:   0.8,
                 ranking:              #LOW }
      LastName,

      @UI: { hidden: true }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      ContactPersonDepartment,

      @UI: { lineItem: { position: 40 } }
      @EndUserText: { label:     'Department',
                      quickInfo: 'Department of Contact Person' }
      _ContactPersonDepartment._Text[1:Language = $session.system_language].ContactPersonDepartmentName,

      @UI: { hidden: true }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      ContactPersonFunction,

      @UI: { lineItem: { position: 50 } }
      @EndUserText: { label:     'Function',
                      quickInfo: 'Function of Contact Person' }
      _ContactPersonFunction._Text[1:Language = $session.system_language].ContactPersonFunctionName,

      @UI: { lineItem: { position: 60 } }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      PhoneNumber,

      @UI: { lineItem: { position: 70 } }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      @EndUserText: { quickInfo: 'Mobile Phone Number',
                      label:     'Mobile Phone Number' }
      MobilePhoneNumber,

      @UI: { lineItem: { position: 80 } }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      FaxNumber,

      @UI: { lineItem: { position: 90 } }
      @Consumption: { valueHelpDefault: { binding: { usage: #FILTER_AND_RESULT } } }
      EmailAddress,

      // Exposed Associations

      @UI: { hidden: true }
      _BusinessPartnerCompany,

      @UI: { hidden: true }
      _BusinessPartnerPerson,

      @UI: { hidden: true }
      _ContactPersonDepartment,

      @UI: { hidden: true }
      _ContactPersonFunction,

      // Exposed Associations

      _BPRelationship,
      _BusinessPartnerCompanyVH,
      _BusinessPartnerPersonVH

}

where
  _BPRelationship.RelationshipCategory is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPRELATIONSHIP",
"I_CONTACTPERSONDEPARTMENT",
"I_CONTACTPERSONDEPARTMENTT",
"I_CONTACTPERSONFUNCTION",
"I_CONTACTPERSONFUNCTIONT",
"I_CUSTOMERCONTACT"
],
"ASSOCIATED":
[
"I_BPRELATIONSHIP",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERVH",
"I_CONTACTPERSONDEPARTMENT",
"I_CONTACTPERSONFUNCTION"
],
"BASE":
[
"I_CUSTOMERCONTACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/