I_CollectionsContactVH

@AbapCatalog: { sqlViewName: 'ICOLLSCNTVH',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Collections Contact Value Help' }
@VDM: { viewType: #COMPOSITE }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory: #S,
                             dataClass: #TRANSACTIONAL },
                dataCategory: #VALUE_HELP,
                representativeKey: 'BusinessPartnerPerson' }
@Search: { searchable: true }
@Consumption: { ranked: true }

define view I_CollectionsContactVH
  as select from I_CollectionContact

  // VDM Associations

  // Business Partner Company Value Help

  association [0..1] to I_BusinessPartnerVH as _BusinessPartnerCompanyVH on $projection.BusinessPartnerCompany = _BusinessPartnerCompanyVH.BusinessPartner

  // Business Partner Person Value Help

  association [0..1] to I_BusinessPartnerVH as _BusinessPartnerPersonVH  on $projection.BusinessPartnerPerson = _BusinessPartnerPersonVH.BusinessPartner

{

      // VDM Fields

      @UI: { hidden: true }
  key RelationshipNumber,

      @UI: { lineItem: [ { position:   110,
                           importance: #LOW } ] }
      @Consumption: { valueHelpDefinition: [ { association: '_BusinessPartnerCompanyVH' } ] }
  key BusinessPartnerCompany,

      @UI: { hidden: true }
      @Consumption: { valueHelpDefinition: [ { association: '_BusinessPartnerPersonVH' } ] }
  key BusinessPartnerPerson,

      @UI: { lineItem: [ { position:   100,
                           importance: #LOW } ] }
  key CollectionSegment,

      @UI: { lineItem: [ { position:   10,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #HIGH,
                 fuzzinessThreshold:    0.8 }
      ContactPerson,

      @UI: { lineItem: [ { position:   20,
                           importance: #HIGH } ] }
      cast( concat_with_space( FirstName, LastName, 1 ) as bdm_contact_name )                           as ContactPersonName,

      @UI: { lineItem: [ { position: 30,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      PhoneNumber,

      @UI: { lineItem: [ { position: 40,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      MobileNumber,

      @UI: { lineItem: [ { position: 50,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      FaxNumber,

      @UI: { lineItem: [ { position: 60,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      EmailAddress,

      @UI: { lineItem: [ { position: 70,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @Consumption: { filter: { hidden: true } }
      @EndUserText: { label: 'Department' }
      _ContactPersonDepartment._Text[1:Language = $session.system_language].ContactPersonDepartmentName as ContactPersonDepartmentName,

      @UI: { lineItem: [ { position: 80,
                           importance: #HIGH } ] }
      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @Consumption: { filter: { hidden: true } }
      @EndUserText: { label: 'Function' }
      _ContactPersonFunction._Text[1:Language = $session.system_language].ContactPersonFunctionName     as ContactPersonFunctionName,

      @Consumption: { valueHelpDefinition: [ { entity: { name:    'I_ContactPersonFunction',
                                                         element: 'ContactPersonFunction' } } ] }
      @ObjectModel: { text: { element: [ 'ContactPersonFunctionName' ] } }
      @UI: { hidden: true }
      ContactPersonFunction,

      @Consumption: { valueHelpDefinition: [ { entity: { name:    'I_ContactPersondepartment',
                                                         element: 'ContactPersonDepartment' } } ] }
      @ObjectModel: { text: { element: [ 'ContactPersonDepartmentName' ] } }
      @UI: { hidden: true }
      ContactPersonDepartment,

      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @UI: { hidden: true }
      FirstName,

      @Search: { defaultSearchElement:  true,
                 ranking:               #LOW,
                 fuzzinessThreshold:    0.8 }
      @UI: { hidden: true }
      LastName,

      // Exposed Associations

      _BusinessPartnerCompany,
      _BusinessPartnerPerson,
      _ContactPersonDepartment,
      _ContactPersonFunction,
      _CollectionSegment,
      _BusinessPartnerCompanyVH,
      _BusinessPartnerPersonVH

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COLLECTIONCONTACT",
"I_CONTACTPERSONDEPARTMENT",
"I_CONTACTPERSONDEPARTMENTT",
"I_CONTACTPERSONFUNCTION",
"I_CONTACTPERSONFUNCTIONT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERVH",
"I_COLLECTIONSEGMENT",
"I_CONTACTPERSONDEPARTMENT",
"I_CONTACTPERSONFUNCTION"
],
"BASE":
[
"I_COLLECTIONCONTACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/