I_CntrlPurContrVersionHistory

@AbapCatalog.sqlViewName: 'IVERSIONHISTORY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Basic View for CCTR Version History'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel:{
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #L,
  usageType.dataClass: #TRANSACTIONAL
}
@VDM.viewType: #BASIC

@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_CntrlPurContrVersionHistory 

  as select from erev as VersionHistory
    inner join R_CentralPurchaseContract as Document on    VersionHistory.edokn                =  Document.ActivePurchasingDocument
                                                     and   VersionHistory.revno                =  Document.PurchasingDocumentVersion
                                                     and ( Document.PurgDocChangeRequestStatus = '1' or  Document.PurgDocChangeRequestStatus = '2' or
                                                           Document.PurgDocChangeRequestStatus = '4' or Document.PurgDocChangeRequestStatus = '' )
                                                   

  association [1..1] to I_User                       as _UserDetails                 on $projection.CreatedByUser = _UserDetails.UserID
  association [1..1] to I_CntrlPurContrVersionType   as _VersionType                 on $projection.PurgDocChangeRequestStatus = _VersionType.PurgDocChangeRequestStatus
  association [0..1] to I_PaymentTermsText           as _PaymentTermsText            on  $projection.PaymentTerms   = _PaymentTermsText.PaymentTerms
                                                                                     and _PaymentTermsText.Language = $session.system_language
{
  key Document.CentralPurchaseContract,
      Document.PurchaseContractType,
      Document.PurchasingDocumentCategory,
      Document.Supplier,
      Document.PurchasingDocumentSubtype,
      Document.CompanyCode,
      Document.PurchasingOrganization,
      Document.PurchasingGroup,
      @Semantics.currencyCode:true
      Document.DocumentCurrency,
      @ObjectModel.readOnly: true
      Document.Currency,
      Document.IncotermsClassification,
      Document.IncotermsTransferLocation,
      Document.PaymentTerms,
      Document.CashDiscount1Days,
      Document.CashDiscount2Days,
      Document.NetPaymentDays,
      Document.CashDiscount1Percent,
      Document.CashDiscount2Percent,
      Document.PurchaseContractTargetAmount,
      Document.ValidityStartDate,
      Document.ValidityEndDate,
      Document.ReleaseCode,
      Document.PurchasingDocumentDeletionCode,
      Document.ManualSupplierAddressID,
      Document.SupplyingSupplier,
      Document.InvoicingParty,
      Document.ExchangeRate ,
      Document.ExchangeRateIsFixed,
      Document.QuotationSubmissionDate,
      Document.SupplierQuotation,
      Document.ReleaseIsNotCompleted,
      Document.CorrespncExternalReference,
      Document.CorrespncInternalReference,
      Document.SupplierRespSalesPersonName,
      Document.SupplierPhoneNumber,
      Document.IncotermsVersion,
      Document.IncotermsLocation1,
      Document.IncotermsLocation2,
      Document.PurchasingDocumentName,
      Document.LastChangeDateTime,
      cast( case when PurgDocumentDistributionType = 'F'
                   then 'X'
                 else ' '
            end as boolean) as CntrlPurContrFlxblDistrIsAllwd,
      Document.PurchasingParentDocument,
      Document.ProcmtHubCompanyCodeGroupingID,
      Document.PurchasingProcessingStatus,
      Document.IsEndOfPurposeBlocked,
      Document.ActivePurchasingDocument,      
      Document.PurgDocChangeRequestStatus,
      Document.PurchasingDocumentVersion,
      Document.PurgDocIsChgVers,
     
      VersionHistory.ernam as CreatedByUser,
      VersionHistory.erdat as CreationDate,
      VersionHistory.eruhr as CreationTime,
      VersionHistory.rscod as PurchasingDocVersionReasonCode,
      VersionHistory.strev as PurchasingDocVersionStatus,
      
      /** Fields for approval details starts...**/
      @ObjectModel.readOnly: true
      cast ('' as mm_oa_approver_id) as AccWorkflowApprover,

      @ObjectModel.readOnly: true
      cast ('' as mm_oa_approver_name) as AccWorkflowApproverFirstName,

      @ObjectModel.readOnly: true
      cast( '' as val_text ) as ApprovalStatusName,

      @ObjectModel.readOnly: true
      cast( '' as sww_aagent ) as ApproverUser,
      /** Fields for approval details ends...**/

      cast('' as boolean ) as PurgContractIsInPreparation,

      @ObjectModel.readOnly: true
      cast('' as mmpur_doc_status) as PurchasingDocumentStatus,  //VDM


      _PurchasingDocumentTypeText,
      _PaymentTermsText,
      _CntrlPurContrStatusText,
      _CntrlPurContrAggrgnDistrSts,
      _UserDetails,
      _VersionType

}
where (  PurgDocChangeRequestStatus = '1' or 
         PurgDocChangeRequestStatus = '2' or
         PurgDocChangeRequestStatus = '4' or 
         PurgDocChangeRequestStatus = '' )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_CENTRALPURCHASECONTRACT",
"EREV"
],
"ASSOCIATED":
[
"I_CNTRLPURCONTRAGGRGNDISTRSTS",
"I_CNTRLPURCONTRDOCSTSTEXT",
"I_CNTRLPURCONTRVERSIONTYPE",
"I_PAYMENTTERMSTEXT",
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_USER"
],
"BASE":
[
"R_CENTRALPURCHASECONTRACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/