I_CnsldtnUnitHierNodeEnhcd_2

@AbapCatalog: {
  sqlViewName: 'ICSUNITHIERED2',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {usageType: {
    dataClass: #MASTER,
    serviceQuality: #D,
    sizeCategory: #L},
  dataCategory: #HIERARCHY
}
@VDM.viewType: #BASIC
@EndUserText.label: 'Consolidation Unit Hierarchy Enhanced 2'
// HL: missing representative key


define view I_CnsldtnUnitHierNodeEnhcd_2
  as select from hrrp_node
  
  association [0..1] to I_CnsldtnUnitHierDirEnhcd as _Hierarchy        on  $projection.ConsolidationUnitHierarchy = _Hierarchy.ConsolidationUnitHierarchy
                                                                       and $projection.ValidityEndDate            = _Hierarchy.ValidityEndDate

  association [0..*] to I_CnsldtnUnitHierNodeT    as _Text             on  $projection.ConsolidationUnitHierarchy = _Text.ConsolidationUnitHierarchy
                                                                       and $projection.HierarchyNode              = _Text.HierarchyNode
                                                                       and $projection.ConsolidationUnit          = ''

  association [0..1] to I_CnsldtnUnitEnhcd_2      as _CnsldtnUnit      on  $projection.ConsolidationUnit      = _CnsldtnUnit.ConsolidationUnit
                                                                       and $projection.ConsolidationDimension = _CnsldtnUnit.ConsolidationDimension

  association [0..1] to I_CnsldtnDimension        as _CnsldtnDimension on  $projection.ConsolidationDimension = _CnsldtnDimension.ConsolidationDimension

{
       @ObjectModel.foreignKey.association: '_Hierarchy'
       //key cast( substring( hryid, 6, 20 ) as fincs_hryid )                                          as ConsolidationUnitHierarchy,

  key  hryid                                        as ConsolidationUnitHierarchy,
       @ObjectModel.text.association: '_Text'
  key  hrynode                                      as HierarchyNode,

       @Semantics.businessDate.to: true
  key  hryvalto                                     as ValidityEndDate,

       @Semantics.businessDate.from: true
       hryvalfrom                                   as ValidityStartDate,

       parnode                                      as ParentNode,

       @ObjectModel.foreignKey.association: '_CnsldtnDimension'
       cast( left( nodecls, 2 ) as fc_dimen )       as ConsolidationDimension,

       @ObjectModel.foreignKey.association: '_CnsldtnUnit'
       cast( case nodetype
        when 'L'  then left( nodevalue, 18 )
        else ''
       end as fc_bunit )                            as ConsolidationUnit,

       hryseqnbr                                    as HierarchyNodeSequence,
       hrylevel                                     as HierarchyNodeLevel,
       
       @Consumption.hidden: true
       cast(substring( hryid, 1, 4) as fincs_hryid) as HierarchyType,
       
       nodetype                                     as NodeType,
       
       _CnsldtnUnit,
       _CnsldtnDimension,
       _Text,
       _Hierarchy
}
where
      nodetype <> 'D'
  and nodetype <> 'B'
  and nodetype <> 'J'
  and nodetype <> 'V'
  and nodetype <> '$'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_CNSLDTNDIMENSION",
"I_CNSLDTNUNITENHCD_2",
"I_CNSLDTNUNITHIERDIRENHCD",
"I_CNSLDTNUNITHIERNODET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/