I_CnsldtnUnitHierForElimEnhcd

@AbapCatalog.sqlViewName: 'ICSUNITELIMH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Consolidation Unit Hierarchy For Elimination'
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #D,
  sizeCategory: #L},
  dataCategory: #HIERARCHY
}
define view I_CnsldtnUnitHierForElimEnhcd as select from hrrp_node 
association [0..1] to I_CnsldtnUnitHierDir as _Hierarchy  on $projection.ConsolidationUnitHierarchy = _Hierarchy.ConsolidationUnitHierarchy
                                                         and $projection.ValidityEndDate = _Hierarchy.ValidityEndDate
                                                         
association [0..*] to I_CnsldtnUnitHierNodeT as _Text on $projection.ConsolidationUnitHierarchy =  _Text.ConsolidationUnitHierarchy
                                                     and $projection.HierarchyNode = _Text.HierarchyNode
                                                     and $projection.ConsolidationUnit = ''
                                                                                                                                                 
association [0..1] to I_CnsldtnUnitForElimination as _CnsldtnUnitForElim  on $projection.ConsolidationUnit = _CnsldtnUnitForElim.ConsolidationUnit
                                                                         and $projection.ConsolidationDimension = _CnsldtnUnitForElim.ConsolidationDimension

association [0..1] to I_CnsldtnDimension  as _CnsldtnDimension on  $projection.ConsolidationDimension = _CnsldtnDimension.ConsolidationDimension
  

{
      
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
      //key cast( substring( hryid, 6, 20 ) as fincs_hryid )                                          as ConsolidationUnitHierarchy,     

  key  hryid                                           as ConsolidationUnitHierarchy,
      @ObjectModel.text.association: '_Text'
      key hrynode                                                                                   as HierarchyNode,
      
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      key hryvalto                                                                                  as ValidityEndDate,      

      @Semantics.businessDate.from: true
      hryvalfrom                                                                                    as ValidityStartDate,
     
      parnode                                                                                       as ParentNode,

      @ObjectModel.foreignKey.association: '_CnsldtnDimension' 
      cast( left( nodecls, 2 ) as fc_dimen )                                                        as ConsolidationDimension,
      
      @ObjectModel.foreignKey.association: '_CnsldtnUnitForElim'
      cast( case nodetype
      when 'L'  then left( nodevalue, 18 )
      when '$'  then nodevalue
      else '' 
      end as fincs_elimination_member )                                                             as ConsolidationUnit,
      
      hrrp_node.hryseqnbr                                                                           as HierarchyNodeSequence,
      hrylevel                                                                                      as HierarchyNodeLevel, 
      nodetype as NodeType, 
      
      _CnsldtnUnitForElim,
      _CnsldtnDimension,
      _Text,
      _Hierarchy
}
where  nodetype <> 'D' and nodetype <> 'B' and nodetype <> 'J' and nodetype <> 'V';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_CNSLDTNDIMENSION",
"I_CNSLDTNUNITFORELIMINATION",
"I_CNSLDTNUNITHIERDIR",
"I_CNSLDTNUNITHIERNODET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/