I_CnsldtnUnitForElimHierNode_2

@AbapCatalog:{
  sqlViewName: 'ICSUNITELIMHNOD2',
  compiler.compareFilter: true
  }
@Analytics: {
  dataExtraction.enabled: true
}
@Hierarchy.parentChild: [{
  recurse:          { parent:    'ParentNode',
                      child:     'HierarchyNode'   },
  siblingsOrder:    [{ by:        'HierarchyNodeSequence',
                      direction: #ASC   }],
  directory:        '_Hierarchy'
}]
@AccessControl:{
  authorizationCheck: #MANDATORY
  }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata:{
  ignorePropagatedAnnotations: true
  }
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #M},
  dataCategory: #HIERARCHY,
  representativeKey: 'HierarchyNode',
  modelingPattern: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE
                          ]
}
@VDM.viewType: #BASIC
@EndUserText.label: 'Cnsldtn Unit for Mgmt Elim - Hier Node'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view I_CnsldtnUnitForElimHierNode_2
  as select from hrrp_node

  association [0..1] to I_CnsldtnUnitForElimination_2 as _CnsldtnUnit on  $projection.ConsolidationUnit = _CnsldtnUnit.ConsolidationUnit

  association [1..1] to I_CnsldtnUnitHierarchy        as _Hierarchy   on  $projection.ConsolidationUnitHierarchy = _Hierarchy.ConsolidationUnitHierarchy
                                                                      and $projection.ValidityEndDate            = _Hierarchy.ValidityEndDate

  association [0..*] to I_CnsldtnUnitHierNodeText_2   as _Text        on  $projection.ConsolidationUnitHierarchy = _Text.ConsolidationUnitHierarchy
                                                                      and $projection.HierarchyNode              = _Text.HierarchyNode
                                                                      and $projection.ConsolidationUnit          = ''

{

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast(left(hrrp_node.hryid, 40) as fincs_consolidationunithier preserving type ) as ConsolidationUnitHierarchy,

      @ObjectModel.text.association: '_Text'
  key hrrp_node.hrynode                                                               as HierarchyNode,

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @Semantics.businessDate.to: true
  key hrrp_node.hryvalto                                                              as ValidityEndDate,

      @Semantics.businessDate.from: true
      hrrp_node.hryvalfrom                                                            as ValidityStartDate,

      hrrp_node.parnode                                                               as ParentNode,

      hrrp_node.hryver                                                                as HierarchyVersion,

      @ObjectModel.foreignKey.association: '_CnsldtnUnit'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_CnsldtnUnitForEliminationVH',
          element: 'ConsolidationUnit'
        }
      }]
      cast( case hrrp_node.nodetype
        when 'L'  then left( hrrp_node.leafvalue, 18 )
        when '$'  then left( hrrp_node.nodevalue, 25 )
        else ''
      end as fincs_elim_unit preserving type )                                        as ConsolidationUnit,

      hrrp_node.hryseqnbr                                                             as HierarchyNodeSequence,
      hrrp_node.hrylevel                                                              as HierarchyNodeLevel,
      hrrp_node.nodetype                                                              as NodeType,


      _Text,
      _CnsldtnUnit,
      _Hierarchy
}
where
  (
         hrrp_node.nodecls  = 'Y1'
    and  hrrp_node.hrytype  = 'CS17'
    and(
         hrrp_node.nodetype = 'R'
      or hrrp_node.nodetype = 'N'
      or hrrp_node.nodetype = 'L'
      or hrrp_node.nodetype = '$'
    )
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_CNSLDTNUNITFORELIMINATION_2",
"I_CNSLDTNUNITHIERARCHY",
"I_CNSLDTNUNITHIERNODETEXT_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/