I_CnsldtnUnitElimNodeText

DDL: I_CNSLDTNUNITELIMNODETEXT Type: view BASIC

Cnsldtn Unit Mgmt Elim Node - Text

I_CnsldtnUnitElimNodeText is a Basic CDS View that provides data about "Cnsldtn Unit Mgmt Elim Node - Text" in SAP S/4HANA. It reads from 2 data sources (hrrp_node, hrrp_nodet) and exposes 5 fields with key fields Language, ConsolidationUnit. It has 2 associations to related views.

2 data source(s) 5 fields

Data Sources (2)

SourceAliasJoin Type
hrrp_node _node inner
hrrp_nodet _nodet from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_Language _Language $projection.Language = _Language.Language
[1..1] I_CnsldtnUnitElimNode _CnsldtnUnit $projection.ConsolidationUnit = _CnsldtnUnit.ConsolidationUnit

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName ICSUNITELIMNODT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #MANDATORY view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.representativeKey ConsolidationUnit view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
VDM.viewType #BASIC view
EndUserText.label Cnsldtn Unit Mgmt Elim Node - Text view

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY Language hrrp_nodet spras
KEY ConsolidationUnit
ConsolidationUnitMdmText
_Language _Language
_CnsldtnUnit _CnsldtnUnit 
@AbapCatalog:{
  sqlViewName: 'ICSUNITELIMNODT',
  compiler.compareFilter: true,
  preserveKey: true
  }
@Analytics: {
  dataExtraction.enabled: true
}
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #M},
  representativeKey: 'ConsolidationUnit',
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT ]
}
@VDM.viewType: #BASIC
@EndUserText.label: 'Cnsldtn Unit Mgmt Elim Node - Text'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_CnsldtnUnitElimNodeText
  as select from hrrp_nodet as _nodet

    inner join   hrrp_node  as _node on  _nodet.hryid    = _node.hryid
                                     and _nodet.hryvalto = _node.hryvalto
                                     and _nodet.hrynode  = _node.hrynode
                                     and _node.nodetype  = '$'
                                     and _node.hrytype   = 'CS17'
                                     and _node.nodecls   = 'Y1'

  association [1..1] to I_Language            as _Language    on $projection.Language = _Language.Language

  association [1..1] to I_CnsldtnUnitElimNode as _CnsldtnUnit on $projection.ConsolidationUnit = _CnsldtnUnit.ConsolidationUnit

{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key _nodet.spras                                                                 as Language,

      @ObjectModel.foreignKey.association: '_CnsldtnUnit'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_CnsldtnUnitForEliminationVH',
          element: 'ConsolidationUnit'
        }
      }]
  key cast(left(_node.nodevalue, 25) as fincs_elim_unit preserving type )          as ConsolidationUnit,

      @Semantics.text
      cast(left(_nodet.nodetxt, 50) as fincs_description_text_50 preserving type ) as ConsolidationUnitMdmText,


      _Language,
      _CnsldtnUnit
}
where
      _nodet.hrytyp  = 'CS17'
  and _nodet.nodecls = 'Y1';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE",
"HRRP_NODET"
],
"ASSOCIATED":
[
"I_CNSLDTNUNITELIMNODE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More