I_CnsldtnSubassignmentT

DDL: I_CNSLDTNSUBASSIGNMENTT Type: view BASIC

Consolidation Subassignment - Text

I_CnsldtnSubassignmentT is a Basic CDS View that provides data about "Consolidation Subassignment - Text" in SAP S/4HANA. It reads from 1 data source (dd04t) and exposes 4 fields with key field Language. It has 2 associations to related views.

1 data source(s) 4 fields

Data Sources (1)

SourceAliasJoin Type
dd04t dd04t from

Associations (2)

CardinalityTargetAliasCondition
[1] I_Language _Language $projection.Language = _Language.Language
[1] I_CnsldtnSubassignment _CnsldtnSubassignment $projection.CnsldtnSubassignment = _CnsldtnSubassignment.CnsldtnSubassignment

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName ICSSUBASSGMTT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey CnsldtnSubassignment view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
EndUserText.label Consolidation Subassignment - Text view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY Language
CnsldtnSubassignmentText
_CnsldtnSubassignment _CnsldtnSubassignment
_Language _Language 
@AbapCatalog:{
  sqlViewName: 'ICSSUBASSGMTT',
  compiler.compareFilter: true,
  preserveKey: true
  }
@Analytics: {
  dataExtraction.enabled: true
  }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType: {
    dataClass: #CUSTOMIZING,
    serviceQuality: #C,
    sizeCategory: #S},
  dataCategory: #TEXT,
  representativeKey: 'CnsldtnSubassignment',
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT ]
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
  }
@EndUserText.label: 'Consolidation Subassignment - Text'

// no search on code list


/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_CnsldtnSubassignmentT
  as select from dd04t

  association [1] to I_Language             as _Language             on $projection.Language = _Language.Language

  association [1] to I_CnsldtnSubassignment as _CnsldtnSubassignment on $projection.CnsldtnSubassignment = _CnsldtnSubassignment.CnsldtnSubassignment

{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast(ddlanguage as spras preserving type )                     as Language,

      @ObjectModel.foreignKey.association: '_CnsldtnSubassignment'
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CnsldtnSubassignmentVH', element: 'CnsldtnSubassignment' } }]
  key cast(case rollname
    when 'RTCUR' then  'TransactionCurrency'
    when 'FC_BUPTR' then  'PartnerConsolidationUnit'
    when 'FC_SITYP' then  'SubItemCategory'
    when 'FC_SITEM' then 'SubItem'
    when 'MEINS' then 'BaseUnit'
    else ''
    end as fincs_subassignment )                                     as CnsldtnSubassignment,

      @Semantics.text: true
      cast ( scrtext_l as fincs_subassignmenttext preserving type ) as CnsldtnSubassignmentText,


      // associations

      _CnsldtnSubassignment,
      _Language
}
where
  (
       rollname = 'RTCUR'
    or rollname = 'FC_BUPTR'
    or rollname = 'FC_SITYP'
    or rollname = 'FC_SITEM'
    or rollname = 'MEINS'
  )
  and  as4local = 'A'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD04T"
],
"ASSOCIATED":
[
"I_CNSLDTNSUBASSIGNMENT",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More