I_CnsldtnPrftCtrHierNodeInElim

@AbapCatalog: {
    sqlViewName: 'ICCPCHNFORELIM',
    compiler.compareFilter:true
}
@Hierarchy.parentChild: {
  recurse:          { parent:    'ParentNode',
                      child:     'HierarchyNode'   },
  siblingsOrder:    [{ by:       'HierarchyNodeSequence',
                      direction: #ASC   }],
  directory:        '_Hierarchy'
}
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #XL},
  dataCategory: #HIERARCHY
  }
@VDM.viewType: #BASIC
@EndUserText.label: 'Cnsldtn Profit Ctr For Elim - HierNode'

define view I_CnsldtnPrftCtrHierNodeInElim
  as select from hrrp_node

  association [0..*] to I_CnsldtnProfitCenterHierNodeT as _Text                on  $projection.ControllingArea               = _Text.ControllingArea
                                                                               and $projection.AdditionalMasterDataHierarchy = _Text.ConsolidationPrftCtrHierarchy
                                                                               and $projection.HierarchyNode                 = _Text.HierarchyNode
                                                                               and $projection.ProfitCenter                  = ''

  association [0..1] to I_CnsldtnProfitCenterForElim   as _ProfitCenterForElim on  $projection.ProfitCenter    = _ProfitCenterForElim.ProfitCenter
                                                                               and $projection.ControllingArea = _ProfitCenterForElim.ControllingArea


  association [1..1] to I_CnsldtnProfitCenterHierarchy as _Hierarchy           on  $projection.AdditionalMasterDataHierarchy = _Hierarchy.ConsolidationPrftCtrHierarchy
                                                                               and $projection.ControllingArea               = _Hierarchy.ControllingArea
                                                                               and $projection.ValidityEndDate               = _Hierarchy.ValidityEndDate


  association [0..1] to I_CnsldtnControllingArea       as _ControllingArea     on  $projection.ControllingArea = _ControllingArea.ControllingArea

{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_ControllingArea' //Inserted by VDM CDS Suite Plugin

  key cast( left(hrrp_node.nodecls, 4) as fis_kokrs preserving type ) as ControllingArea,

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast(hrrp_node.hryid as hryid preserving type)                  as AdditionalMasterDataHierarchy,

      @ObjectModel.text.association: '_Text'
  key hrrp_node.hrynode                                               as HierarchyNode,

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
  key cast(hrrp_node.hryvalto as fis_datbi preserving type)           as ValidityEndDate,

      hrrp_node.parnode                                               as ParentNode,
      hrrp_node.hryver                                                as HierarchyVersion,

      @Semantics.businessDate.from: true
      cast(hrrp_node.hryvalfrom as fis_datab preserving type)         as ValidityStartDate,

      @ObjectModel.foreignKey.association: '_ProfitCenterForElim'
      cast ( case nodetype
        when 'L' then  substring( hrrp_node.nodevalue, 1, 10 )
        when '$'  then nodevalue
        else  ''
      end as fincs_elimination_member )                               as ProfitCenter,

      hrrp_node.hryseqnbr                                             as HierarchyNodeSequence,
      hrrp_node.hrylevel                                              as HierarchyNodeLevel,
      hrrp_node.nodetype                                              as NodeType,


      _Text,
      _ProfitCenterForElim,
      _Hierarchy,
      _ControllingArea

}
where
      nodetype <> 'D'
  and nodetype <> 'B'
  and nodetype <> 'J'
  and nodetype <> 'V';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_CNSLDTNCONTROLLINGAREA",
"I_CNSLDTNPROFITCENTERFORELIM",
"I_CNSLDTNPROFITCENTERHIERARCHY",
"I_CNSLDTNPROFITCENTERHIERNODET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/