I_CnsldtnFinTransTypeT

@AbapCatalog.sqlViewName: 'ICSFINTRANSTYPET'
@Analytics: {
  dataExtraction.enabled: true
}
@AccessControl:{
  authorizationCheck: #MANDATORY
  }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #S },
  representativeKey: 'FinancialTransactionType',
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT ]
}
@VDM:{
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
  }
@EndUserText.label: 'Cnsldtn Cmbnd Fin Transaction Type - Txt'

define view I_CnsldtnFinTransTypeT
  as select distinct from P_CnsldtnFinTransTypeT as _Source

    inner join            I_CnsldtnFinTransType  as _Main on  _Main.FinancialTransactionType      = _Source.FinancialTransactionType
                                                          and _Main.CnsldtnIsAdditionalMasterData = _Source.CnsldtnIsAdditionalMasterData

  association [1..1] to I_Language            as _Language     on $projection.Language = _Language.Language

  association [1..1] to I_CnsldtnFinTransType as _FinTransType on $projection.FinancialTransactionType = _FinTransType.FinancialTransactionType

{

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language
  key _Source.Language,

      @ObjectModel.foreignKey.association: '_FinTransType'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_CnsldtnFinTransTypeVH',
          element: 'FinancialTransactionType'
        }
      }]
  key cast( _Source.FinancialTransactionType as fincs_financialtransactiontype preserving type )    as FinancialTransactionType,

      @API.element: {releaseState: #DEPRECATED, successor: 'CnsldtnIsAdditionalMasterData'}
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'CnsldtnIsAdditionalMasterData' }
      cast( _Source.AdditionalMasterDataSource as fincs_masterdatasource preserving type )          as AdditionalMasterDataSource,

      @Semantics.text
      @API.element: {releaseState: #DEPRECATED, successor: 'FinancialTransactionTypeName'}
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'FinancialTransactionTypeName' }
      cast ( _Source.FinancialTransactionTypeName as fincs_description_text_20 preserving type )    as AdditionalMasterDataText,

      @Semantics.text
      cast( _Source.FinancialTransactionTypeName as fincs_financialtranstype_desc preserving type ) as FinancialTransactionTypeName,

      _Source.CnsldtnIsAdditionalMasterData,


      /* associations */
      _Language,
      _FinTransType
}
where
  _Source.Language is not null;
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNFINTRANSTYPE",
"P_CNSLDTNFINTRANSTYPET"
],
"ASSOCIATED":
[
"I_CNSLDTNFINTRANSTYPE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/