I_CnsldtnDocTypeHierarchyT_2

DDL: I_CNSLDTNDOCTYPEHIERARCHYT_2 Type: view BASIC

Cnsldtn Document Type Hierarchy - Text

I_CnsldtnDocTypeHierarchyT_2 is a Basic CDS View that provides data about "Cnsldtn Document Type Hierarchy - Text" in SAP S/4HANA. It reads from 2 data sources (hrrp_directoryt, hrrp_directory) and exposes 6 fields with key fields Language, ConsolidationDocTypeHierarchy, ValidityEndDate. It has 1 association to related views.

2 data source(s) 6 fields

Data Sources (2)

SourceAliasJoin Type
hrrp_directoryt _HierarchyText from
hrrp_directory hrrp_directory inner

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_Language _Language $projection.Language = _Language.Language

Annotations (15)

NameValueLevelField
AbapCatalog.sqlViewName ICCDOCTYPEHDIRT2 view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
Analytics.dataExtraction.enabled true view
AccessControl.authorizationCheck #CHECK view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey ConsolidationDocTypeHierarchy view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
VDM.viewType #BASIC view
EndUserText.label Cnsldtn Document Type Hierarchy - Text view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language hrrp_directoryt spras
KEY ConsolidationDocTypeHierarchy
KEY ValidityEndDate
ValidityStartDate
ConsolidationDocTypeHierTxt
_Language _Language 
@AbapCatalog: {
  sqlViewName: 'ICCDOCTYPEHDIRT2',
  compiler.compareFilter: true,
  preserveKey: true
}
@Analytics: {
  dataExtraction.enabled: true
}
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:{
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #M},
  dataCategory: #TEXT,
  representativeKey: 'ConsolidationDocTypeHierarchy',
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,                          
                          #LANGUAGE_DEPENDENT_TEXT ]
  }
@VDM: {viewType: #BASIC }
@EndUserText.label: 'Cnsldtn Document Type Hierarchy - Text'

define view I_CnsldtnDocTypeHierarchyT_2
  as select from hrrp_directoryt as _HierarchyText

    inner join   hrrp_directory on  hrrp_directory.hryid    = _HierarchyText.hryid
                                and hrrp_directory.hryver   = _HierarchyText.hryver
                                and hrrp_directory.hryvalto = _HierarchyText.hryvalto

  association [1..1] to I_Language as _Language on $projection.Language = _Language.Language

{
        @ObjectModel.foreignKey.association: '_Language'
        @Semantics.language
  key   _HierarchyText.spras                                                        as Language,

  key   cast(_HierarchyText.hryid as fincs_doctypehierarchy preserving type )       as ConsolidationDocTypeHierarchy,

        @Semantics.businessDate.to: true
  key   cast(_HierarchyText.hryvalto as fincs_validityenddate preserving type )     as ValidityEndDate,

        @Semantics.businessDate.from: true
        cast(_HierarchyText.hryvalfrom as fincs_validitystartdate preserving type ) as ValidityStartDate,

        @Semantics.text: true
        cast(_HierarchyText.hrytxt as fincs_hierarchytext preserving type )         as ConsolidationDocTypeHierTxt,


        _Language
}
where
  _HierarchyText.hrytype = 'CS19';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIRECTORY",
"HRRP_DIRECTORYT"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More