I_CnsldtnDocTypeHierNode_2

@AbapCatalog: {
  sqlViewName: 'ICCDOCTYPEHNODE2',
  compiler.compareFilter: true  ,
  preserveKey: true
}
@Analytics: {
  dataExtraction.enabled: true
}
@Hierarchy.parentChild: {
  recurse:          { parent:    'ParentNode',  child: 'HierarchyNode'   },
  siblingsOrder:    { by:        'HierarchyNodeSequence', direction: #ASC   },
  directory:        '_Hierarchy'
}
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #M},
  dataCategory: #HIERARCHY,
  representativeKey: 'HierarchyNode',
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SQL_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,                          
                          #ANALYTICAL_DIMENSION ]
  }
@VDM.viewType: #BASIC
@EndUserText.label: 'Cnsldtn Document Type - Hierarchy Node'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_CnsldtnDocTypeHierNode_2
  as select from hrrp_node as _HierarchyNode

  association [0..*] to I_CnsldtnDocTypeHierNodeT_2 as _Text         on  $projection.ConsolidationDocTypeHierarchy = _Text.ConsolidationDocTypeHierarchy
                                                                     and $projection.HierarchyNode                 = _Text.HierarchyNode
                                                                     and $projection.ConsolidationDocumentType     = ''

  association [1..1] to I_CnsldtnDocTypeHierarchy_2 as _Hierarchy    on  $projection.ConsolidationDocTypeHierarchy = _Hierarchy.ConsolidationDocTypeHierarchy
                                                                     and $projection.ValidityEndDate               = _Hierarchy.ValidityEndDate

  association [0..1] to I_CnsldtnDocumentType_2     as _DocumentType on  $projection.ConsolidationDocumentType = _DocumentType.ConsolidationDocumentType

{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast(_HierarchyNode.hryid as fincs_doctypehierarchy preserving type )           as ConsolidationDocTypeHierarchy,

      @ObjectModel.text.association: '_Text'
  key cast(_HierarchyNode.hrynode as fincs_hierarchynode preserving type )            as HierarchyNode,

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @Semantics.businessDate.to: true
  key cast(_HierarchyNode.hryvalto as fincs_validityenddate preserving type )         as ValidityEndDate,

      @Semantics.businessDate.from: true
      cast(_HierarchyNode.hryvalfrom as fincs_validitystartdate preserving type )     as ValidityStartDate,

      cast(_HierarchyNode.parnode as fincs_parentnode preserving type )               as ParentNode,

      cast(_HierarchyNode.hryver as fincs_hierarchyversion preserving type )          as HierarchyVersion,

      @ObjectModel.foreignKey.association: '_DocumentType'
      cast( left(_HierarchyNode.leafvalue, 2) as fincs_documenttype preserving type ) as ConsolidationDocumentType,

      _HierarchyNode.hryseqnbr                                                        as HierarchyNodeSequence,
      _HierarchyNode.hrylevel                                                         as HierarchyNodeLevel,
      _HierarchyNode.nodetype                                                         as NodeType,


      _DocumentType,
      _Text,
      _Hierarchy
}
where
       _HierarchyNode.hrytype  = 'CS19'
  and(
       _HierarchyNode.nodetype = 'R'
    or _HierarchyNode.nodetype = 'N'
    or _HierarchyNode.nodetype = 'L'
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE"
],
"ASSOCIATED":
[
"I_CNSLDTNDOCTYPEHIERARCHY_2",
"I_CNSLDTNDOCTYPEHIERNODET_2",
"I_CNSLDTNDOCUMENTTYPE_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/