I_CndnContrSettlmtStatusText

DDL: I_CNDNCONTRSETTLMTSTATUSTEXT Type: view_entity BASIC

Condition Contract Settlement Status Txt

I_CndnContrSettlmtStatusText is a Basic CDS View that provides data about "Condition Contract Settlement Status Txt" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields Language, CndnContrSettlmtStatus. It has 1 association to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (14)

NameValueLevelField
EndUserText.label Condition Contract Settlement Status Txt view
AccessControl.authorizationCheck #NOT_REQUIRED view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey CndnContrSettlmtStatus view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Search.searchable true view
Analytics.dataExtraction.enabled false view
Analytics.technicalName IWCBCCSETSTSTXT view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY CndnContrSettlmtStatus
DomainValue dd07t domvalue_l
CndnContrSettlmtStatusName
_CndnContrSettlmtStatus _CndnContrSettlmtStatus
_Language _Language 
@EndUserText.label: 'Condition Contract Settlement Status Txt'
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED
}
@ObjectModel: {
  dataCategory: #TEXT,
  representativeKey: 'CndnContrSettlmtStatus',
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT,
                          #SQL_DATA_SOURCE,
                          #CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SEARCHABLE_ENTITY],
  usageType: {
    dataClass:      #META,
    serviceQuality: #A,
    sizeCategory:   #S
  }
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Search.searchable: true
@Analytics: {
  dataExtraction.enabled: false, 
  technicalName: 'IWCBCCSETSTSTXT'
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_CndnContrSettlmtStatusText
  as select from dd07t
  
  association        to parent I_CndnContrSettlmtStatus as _CndnContrSettlmtStatus on $projection.CndnContrSettlmtStatus = _CndnContrSettlmtStatus.CndnContrSettlmtStatus
  association [0..1] to I_Language                      as _Language               on $projection.Language = _Language.Language

{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )                    as Language,

      @ObjectModel.foreignKey.association: '_CndnContrSettlmtStatus'
      @ObjectModel.text.element: ['CndnContrSettlmtStatusName']
  key cast( dd07t.domvalue_l as wcb_cc_settlement_state )                  as CndnContrSettlmtStatus,

      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                     as DomainValue,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as wcb_cc_settlement_state_text preserving type ) as CndnContrSettlmtStatusName,

      /* Associations */
      _CndnContrSettlmtStatus,
      _Language
}

where
      dd07t.domname  = 'WCB_CC_SETTLEMENT_STATE'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CNDNCONTRSETTLMTSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More