I_CndnContrIsInactiveText

DDL: I_CNDNCONTRISINACTIVETEXT Type: view_entity BASIC

Condition Contract Inactive State - Text

I_CndnContrIsInactiveText is a Basic CDS View that provides data about "Condition Contract Inactive State - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields CndnContrIsInactive, Language. It has 1 association to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (14)

NameValueLevelField
EndUserText.label Condition Contract Inactive State - Text view
AccessControl.authorizationCheck #NOT_REQUIRED view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey CndnContrIsInactive view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
Search.searchable true view
Analytics.internalName #LOCAL view
Analytics.technicalName IWCBCCSTATET view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY CndnContrIsInactive
KEY Language dd07t ddlanguage
CndnContrIsInactiveName
DomainValue dd07t domvalue_l
_CndnContrIsInactive _CndnContrIsInactive
_Language _Language 
@EndUserText.label: 'Condition Contract Inactive State - Text'
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED
}
@ObjectModel: {
  dataCategory: #TEXT,
  representativeKey: 'CndnContrIsInactive',
  modelingPattern:        #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT,
                          #SQL_DATA_SOURCE,
                          #CDS_MODELING_DATA_SOURCE,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #SEARCHABLE_ENTITY],
  usageType: {
    dataClass:      #META,
    serviceQuality: #A,
    sizeCategory:   #S
  }
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Search.searchable: true
@Analytics: {
  internalName: #LOCAL,
  technicalName: 'IWCBCCSTATET'
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_CndnContrIsInactiveText
  as select from dd07t

  association        to parent I_CndnContrIsInactive as _CndnContrIsInactive on $projection.CndnContrIsInactive = _CndnContrIsInactive.CndnContrIsInactive
  association [0..1] to I_Language                   as _Language            on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_CndnContrIsInactive'
      @ObjectModel.text.element: ['CndnContrIsInactiveName']
  key cast(substring(dd07t.domvalue_l, 1, 1) as wcb_cc_state preserving type ) as CndnContrIsInactive,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key dd07t.ddlanguage                                                         as Language,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as wcb_cc_state_name preserving type )                as CndnContrIsInactiveName,
      @Consumption.hidden: true
      dd07t.domvalue_l                                                         as DomainValue,

      /* Associations */
      _CndnContrIsInactive,
      _Language
}
where
      dd07t.domname  = 'WCB_CC_STATE'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CNDNCONTRISINACTIVE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More