I_CnConSettlementLockStatusT

@EndUserText.label: 'Cndn Contr Settlmt Lock Status - Txt'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: {
  dataCategory: #TEXT,
  representativeKey: 'CnConSettlementLockStatus',
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  supportedCapabilities: [
    #CDS_MODELING_ASSOCIATION_TARGET,
    #CDS_MODELING_DATA_SOURCE,
    #EXTRACTION_DATA_SOURCE,
    #LANGUAGE_DEPENDENT_TEXT,
    #SEARCHABLE_ENTITY,
    #SQL_DATA_SOURCE
  ],
  usageType: {
    serviceQuality: #A,
    dataClass: #META,
    sizeCategory: #S
  }
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Search.searchable: true
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_CnConSettlementLockStatusT
  as select from dd07t

  association        to parent I_CnConSettlementLockStatus as _CnConSettlementLockStatus on $projection.CnConSettlementLockStatus = _CnConSettlementLockStatus.CnConSettlementLockStatus

  association [0..1] to I_Language                         as _Language                  on $projection.Language = _Language.Language

{
      @ObjectModel.foreignKey.association: '_CnConSettlementLockStatus'
      @ObjectModel.text.element: ['CnConSettlementLockStatusName']
  key cast(dd07t.domvalue_l as wcb_cc_status_settl_locked) as CnConSettlementLockStatus,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )                                      as Language,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                                       as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as wcb_cc_status_settl_locked_fio preserving type )                 as CnConSettlementLockStatusName,

      /* Associations */
      _CnConSettlementLockStatus,
      _Language
}
where
      dd07t.domname  = 'WCB_CC_STATUS_SETTL_LOCKED'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CNCONSETTLEMENTLOCKSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/