I_CmplRqRsltProcgStsTxt

@AbapCatalog.sqlViewName: 'ICRRPSTSTXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@EndUserText.label: 'CRR Processing Status Text'
@Metadata.ignorePropagatedAnnotations: true
-- CDS View Classification: 1. No data access restriction required
-- Reason: Text View for Domain Fix values
@AccessControl.authorizationCheck: #NOT_REQUIRED

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel:
{
  --Data category
    /*
      #TEXT:      the annotated entity represents texts
      #HIERARCHY: the entity represents the hierarchy-related data
    */
  dataCategory: #TEXT,
  representativeKey: 'CmplRqRsltProcessingStatus',

    --Performance Annotations
  usageType:
  {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #C
  }
}

@Search.searchable: true

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view I_CmplRqRsltProcgStsTxt
  as select from dd07t
  association        to parent I_CmplRqRsltProcgStsVH as _ProcessingStatus on $projection.CmplRqRsltProcessingStatus = _ProcessingStatus.CmplRqRsltProcessingStatus
  association [0..1] to I_Language                    as _Language         on $projection.Language = _Language.Language
{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(ddlanguage as spras preserving type ) as Language,
  
      @ObjectModel.foreignKey.association: '_ProcessingStatus'
      @ObjectModel.text.element:['ProcessingStatusText']
  key cast(domvalue_l as ehfnd_crr_proc_status ) as CmplRqRsltProcessingStatus,

      /* Content */
      @Consumption.hidden: true
      domvalue_l                                 as DomainValue,
      
      @Semantics.text: true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      ddtext                                     as ProcessingStatusText,

      /* Associations */
      _Language,
      _ProcessingStatus
}
where
      domname  = 'EHFND_CRR_PROCSTAT'
  and as4local = 'A'
  and as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CMPLRQRSLTPROCGSTSVH",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0
}
}*/