I_CmmdtyDrvtvOrderUserDetails

@AbapCatalog.sqlViewName: 'ICMMDTYUSRDET'
@AbapCatalog.compiler.compareFilter     : true
@AbapCatalog.preserveKey: true
@ClientHandling: {
   type                                 : #CLIENT_DEPENDENT,
   algorithm                            : #SESSION_VARIABLE }
   
@AccessControl: {
  authorizationCheck                    : #CHECK,
  personalData.blocking                 : #REQUIRED
}

@EndUserText.label                      : 'Basic View for User Details'
@VDM.viewType                           : #BASIC
@ObjectModel.usageType.dataClass        : #MASTER
@ObjectModel.usageType.serviceQuality   : 'C'
@ObjectModel.usageType.sizeCategory     : #L
@ObjectModel.representativeKey          : 'UserID'
@VDM.lifecycle.contract.type            : #SAP_INTERNAL_API




define view         I_CmmdtyDrvtvOrderUserDetails as select from usr21 as _User
  left outer join   adrp  as UserAddress  on _User.persnumber = UserAddress.persnumber
  association [0..1] to adrp as _Person                   on  _Person.persnumber = $projection.Person
                                                          and _Person.persnumber <> ''

  association [0..1] to adcp as _OrgData                  on  _OrgData.addrnumber = $projection.AddressID
                                                          and _OrgData.persnumber = $projection.Person

  association [0..1] to adr2 as _DefaultPhoneNumber       on  _DefaultPhoneNumber.addrnumber = $projection.AddressID
                                                          and _DefaultPhoneNumber.persnumber = $projection.Person
                                                          and _DefaultPhoneNumber.r3_user    = '1'

  association [0..1] to adr2 as _DefaultMobilePhoneNumber on  _DefaultMobilePhoneNumber.addrnumber = $projection.AddressID
                                                          and _DefaultMobilePhoneNumber.persnumber = $projection.Person
                                                          and _DefaultMobilePhoneNumber.r3_user    = '3'

  association [0..1] to adr6 as _DefaultEmailAddress      on  _DefaultEmailAddress.addrnumber = $projection.AddressID
                                                          and _DefaultEmailAddress.persnumber = $projection.Person
                                                          and _DefaultEmailAddress.flgdefault = 'X'
  
  
{
    //  @ObjectModel.text.element : 'UserDescription'

   //   @Semantics.contact.type: #PERSON

      @Semantics.organization.role
       key _User.bname                                                                            as UserID,
      _User.persnumber                                                                            as Person,
      _User.bpperson                                                                              as BusinessPartnerUUID,

      @Semantics.name.givenName: true
      _Person.name_first                                                                          as FirstName,

      @Semantics.name.familyName: true
      _Person.name_last                                                                           as LastName,

      @Semantics.name.fullName: true
      cast(coalesce( _Person.name_text , _User.techdesc ) as ad_namtext preserving type )         as FullName,

      _User.addrnumber                                                                            as AddressID,

      @Semantics.telephone.type:  [#PREF, #WORK ]
      cast(_DefaultPhoneNumber.telnr_long as contactcardphonenumber preserving type )             as PhoneNumber,

      @Semantics.telephone.type:  [#PREF, #CELL ]
      cast(_DefaultMobilePhoneNumber.telnr_long as contactcardmobilephonenumber preserving type ) as MobilePhoneNumber,

      @Semantics.eMail.type:  #WORK
      @Semantics.eMail.address: true
      cast(_DefaultEmailAddress.smtp_addr as contactcardemailaddress preserving type )            as EmailAddress,

      @Semantics.organization.name: true
      _OrgData.department                                                                         as Department

     

   
}
 
  

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ADCP",
"ADR2",
"ADR6",
"ADRP",
"USR21"
],
"ASSOCIATED":
[
"ADCP",
"ADR2",
"ADR6",
"ADRP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/