I_ChmlSuplrMatlStatusOriginT

@EndUserText.label: 'Language-Dependent Description of Compliance Status Origin'

@AbapCatalog:
{
  sqlViewName: 'ICSMCRRORIGT',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel:
{
  --Data category
  dataCategory: #TEXT,
  --Performance annotation
  usageType:
  {
    dataClass: #META,
    serviceQuality: #B,
    sizeCategory: #S
  },
  --Representative Key
  representativeKey: 'ChmlCmplncRqmtRsltOrigin'
}

--Search
@Search.searchable: true

define view I_ChmlSuplrMatlStatusOriginT
  --Select data from domain value description table
  as select from dd07t as ComplianceStatusOriginText

  --association to I_Language
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      --Domain Value of Compliance Status Origin
  key substring(ComplianceStatusOriginText.domvalue_l, 1, 3)   as ChmlCmplncRqmtRsltOrigin,

      --Language
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(ComplianceStatusOriginText.ddlanguage as sylangu)   as Language,

      --language-dependent description of domain value
      @Semantics.text: true
      @Search:
      {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.8,
        ranking: #HIGH
      }
      ComplianceStatusOriginText.ddtext                        as ChmlCmplncRqmtRsltOriginName,

      /* Associations */
      _Language
}
where
      ComplianceStatusOriginText.domname  = 'EHFND_CSM_CRR_ORIGIN'
  and ComplianceStatusOriginText.as4local = 'A'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/