I_ChmlCmplncReqTP

@EndUserText.label: 'Chemical Compliance Request'
@AbapCatalog:
{
 sqlViewName: 'ICRQTP',
 compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser', '_RequesterUser' ],
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL 
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
 
@ObjectModel:
{
  transactionalProcessingEnabled: true,
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  writeActivePersistence: 'EHFNDV_CRQ',
  createEnabled: 'EXTERNAL_CALCULATION',
  updateEnabled: 'EXTERNAL_CALCULATION',
  deleteEnabled: 'EXTERNAL_CALCULATION',
  entityChangeStateId: 'LastChangeUTCDateTime',
  sapObjectNodeType.name: 'ProdCmplncLogisticsRequest',
  semanticKey:  [ 'ChmlCmplncRequestUUID' ],

  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view I_ChmlCmplncReqTP
  as select from I_ChmlCmplncReq

  //expected cardinality: don't change 

  association [0..1] to I_ChmlCmplncReqNewCmplncInfoTP  as _NewComplInfo         on $projection.ChmlCmplncRequestUUID = _NewComplInfo.ChmlCmplncRequestUUID
  association [0..*] to I_ChmlCmplncReqMktTP            as _RequestedMarket      on $projection.ChmlCmplncRequestUUID = _RequestedMarket.ChmlCmplncRequestUUID
  association [0..*] to I_ChmlCmplncReqApplicationTP    as _RequestedApplication on $projection.ChmlCmplncRequestUUID = _RequestedApplication.ChmlCmplncRequestUUID
  association [0..*] to I_ChmlCmplncReqPrpsAssgmtTP     as _RequestedPurpose     on $projection.ChmlCmplncRequestUUID = _RequestedPurpose.ChmlCmplncRequestUUID
  association [0..*] to I_ChmlCmplncReqSlsOrgTP         as _RequestedSlsOrg      on $projection.ChmlCmplncRequestUUID = _RequestedSlsOrg.ChmlCmplncRequestUUID
  association [0..*] to I_ChmlCmplncReqPlntTP           as _RequestedPlnt        on $projection.ChmlCmplncRequestUUID = _RequestedPlnt.ChmlCmplncRequestUUID
  association [0..*] to I_ChmlCmplncReqRouteSegmentTP   as _RouteSegment         on $projection.ChmlCmplncRequestUUID = _RouteSegment.ChmlCmplncRequestUUID

{

      @ObjectModel.mandatory: true
  key ChmlCmplncRequestUUID,
      CreationUTCDateTime,
      CreatedByUser,
      LastChangeUTCDateTime,
      LastChangedByUser,

      ChmlCmplncRequestDueDate,
      ChmlCmplncReqCmplncProc, 
      @ObjectModel.mandatory: true
      ChmlCmplncRequestOriginType,
      ChmlCmplncReqOriginProc,
      @ObjectModel.mandatory: true
      ChmlCmplncRequestPrgrsStatus,
      @ObjectModel.mandatory: true
      ChmlCmplncBusinessProcess,

      @ObjectModel.mandatory: true
      ChmlCmplncReqRequester,
      ChmlCmplncReqBPRequester,
      ChmlCmplncReqBPProcessor,

      ChmlCmplncInfoUUID,
      ChmlCmplncProdUUID,
      ChemicalCustomerMaterialUUID,
      
      Material,
      SalesDocument,
      SalesDocumentItem,  
      ChmlCmplncReqLogisticDocCat,
          
      ChmlCmplncRequestRemark,
      
      ChmlCmplncReqDetails,
      
      ProdCmplncLogsDocument,
      ProdCmplncLogsDocumentUUID,
      ProdCmplncLogsDocumentItem,
      BusinessSystemName,
      DngrsGoodsModeOfTransport,
      
      Supplier,

      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _NewComplInfo,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _RequestedMarket,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _RequestedApplication,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _RequestedPurpose,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _RequestedSlsOrg,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _RequestedPlnt,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _RouteSegment,

      _CreatedByUser,
      _LastChangedByUser,
      _Product,
      _ChmlCmplncInfo,
      _ChemicalCustomerMaterial,
      _BusinessUserProcessor,
      _BusinessUserRequester,
      _RequesterUser,
      _ChmlCmplncReqCmplncProc,
      _BusinessProcess,
      _OriginType,
      _OriginProcess,
      _Supplier,
      _RequestStatus

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCMPLNCREQ"
],
"ASSOCIATED":
[
"I_BUSINESSUSERBASIC",
"I_CHEMICALCUSTOMERMATERIAL",
"I_CHMLCMPLNCBUSPROC",
"I_CHMLCMPLNCINFO",
"I_CHMLCMPLNCREQAPPLICATIONTP",
"I_CHMLCMPLNCREQCMPLNCPROC",
"I_CHMLCMPLNCREQMKTTP",
"I_CHMLCMPLNCREQNEWCMPLNCINFOTP",
"I_CHMLCMPLNCREQORIGINPROC",
"I_CHMLCMPLNCREQORIGINTYPE",
"I_CHMLCMPLNCREQPLNTTP",
"I_CHMLCMPLNCREQPRPSASSGMTTP",
"I_CHMLCMPLNCREQROUTESEGMENTTP",
"I_CHMLCMPLNCREQSLSORGTP",
"I_CHMLCMPLNCREQSTATUS",
"I_PRODUCT",
"I_SUPPLIER",
"I_USER"
],
"BASE":
[
"I_CHMLCMPLNCREQ"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/