I_ChmlCmplncReqMkt

@EndUserText.label: 'Requested Market of a Chemical Compliance Request'

@AbapCatalog:
{
  sqlViewName: 'ICCMPLCNREQMREQ',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  },
  representativeKey: 'ChmlCmplncReqMktUUID'
}

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ChmlCmplncReqMkt
  as select from ehfndv_crq_mreq

  association [1..1] to I_ChmlCmplncReq as _ChmlCmplncReq     on $projection.ChmlCmplncRequestUUID = _ChmlCmplncReq.ChmlCmplncRequestUUID

  association [0..1] to I_User          as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User          as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_Country       as _Country           on $projection.Country = _Country.Country

{
  key chmlcmplncreqmktuuid                                                    as ChmlCmplncReqMktUUID,

      chmlcmplncrequestuuid                                                   as ChmlCmplncRequestUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      chmlcmplncprodnisreqd                                                   as ChmlCmplncProdnIsReqd,
      chmlcmplncsalesisreqd                                                   as ChmlCmplncSalesIsReqd,
      @ObjectModel.foreignKey.association: '_Country'
      country                                                                 as Country,

      chmlcmplncreqchgtype                                                    as ChmlCmplncReqChgType,
      
      //Exposed associations

      _ChmlCmplncReq,
      _CreatedByUser,
      _LastChangedByUser,
      _Country
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDV_CRQ_MREQ"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCREQ",
"I_COUNTRY",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/