I_ChmlCmplncAnlyts1

@AbapCatalog.sqlViewName: 'ICCMPLCNINFOA1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@EndUserText.label: 'Chemical Compliance Info for Analytics'

@AccessControl.authorizationCheck: #CHECK

@ClientHandling:
{
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@VDM.viewType: #COMPOSITE

@ObjectModel.usageType:{ serviceQuality: #D,
                         sizeCategory:  #L,
                         dataClass: #MIXED }

/*----------------------------------------------------------------------------------------------------------------------
    Chemical Compliance Information of Unpackaged Product for Analytics
------------------------------------------------------------------------------------------------------------------------*/
define view I_ChmlCmplncAnlyts1
  as select from I_ChmlCmplncInfo  as _ChmlCmplncInfo
  -- inner join to Composition
    inner join   I_ChmlComposition as _ChemicalComposition on  _ChmlCmplncInfo.ChmlCmplncInfoUUID         =  _ChemicalComposition.ChmlCmplncInfoUUID
                                                           and _ChemicalComposition.ChmlCompositionType   <> 'MATLBSD1'
                                                           and _ChemicalComposition.ChmlCompositionType   <> 'MATLBSD2'
                                                           and _ChemicalComposition.ChmlCompositionStatus =  'RE'
{
      -- UUID of Chemical Compliance Information of Unpackaged Product
  key _ChmlCmplncInfo.ChmlCmplncInfoUUID,
      -- UUID of Company Substance
  key _ChemicalComposition._ChmlComponent.SubstanceUUID as SubstanceUUID,
      -- Compostion Type
  key _ChemicalComposition.ChmlCompositionType          as ChmlCompositionType,
      -- Indicator that Material assigned to unpackaged product is primary
  key _MaterialAssignment.MatlAssgmtIsPrimary,
      -- Material assigned to Unpackaged Product
  key _MaterialAssignment.Material,
      -- Product Group of assigned material of Unpackaged Product
      _MaterialAssignment._Product.ProductGroup,

      -- Responsible Unit (used for DCL)
      ProdStewardshipRespUnit                           as ProdStewardshipRespUnit,
      -- Indicator that Material is Sold (used for DCL)
      MaterialIsSold,
      -- Indicator that Material is Transported (used for DCL)
      MaterialIsTransported,
      -- Indicator that Material is Produced (used for DCL)
      MaterialIsProduced,
      -- Indicator that Material is Sourced (used for DCL)
      MaterialIsSourced,
      MaterialIsDisposed,
      MaterialIsEmissionRelevant
}
where
      ChmlCmplncInfoType = 'BU'
  and MaterialIsSold     = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCMPLNCINFO",
"I_CHMLCMPLNCMATLASSGMT",
"I_CHMLCOMPONENT",
"I_CHMLCOMPOSITION",
"I_PRODUCT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/