I_ChgRecdRefOrdSpcfcRoutingTP

@AbapCatalog.sqlViewName: 'ICRREFOSRTGTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Change Record Reference Object Ord Spcfc Rtg'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant','BillOfOperationsVersion'],
                writeDraftPersistence: 'PLMCRREFOSR_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE 
define view I_ChgRecdRefOrdSpcfcRoutingTP
  as select from    I_ChgRecdRefRoutingBsc     as routingReference
    left outer join I_ProductionRoutingVersion as Routing on  routingReference.ChgRecRefInternalKey1 = Routing.BillOfOperationsGroup
                                                          and routingReference.ChgRecRefInternalKey2 = Routing.BillOfOperationsType
                                                          and routingReference.ChgRecRefInternalKey3 = Routing.BillOfOperationsVariant
                                                          and routingReference.ChgRecRefInternalKey4 = Routing.BillOfOperationsVersion
  association [1..1] to I_ChangeRecordDraftTP as _ChangeRecordTP on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
{
  key   routingReference.ChangeRecordReferenceUUID,
        case
           when Routing.BillOfOperationsType is null then cast(SUBSTRING( routingReference.ChangeRecordReference, 9, 1) as plnty)
           else cast(Routing.BillOfOperationsType as plnty)
           end as BillOfOperationsType,

        case
        when Routing.BillOfOperationsGroup is null then  cast(SUBSTRING( routingReference.ChangeRecordReference, 1, 8) as plnnr)
        else cast(Routing.BillOfOperationsGroup as plnnr)
        end    as BillOfOperationsGroup,

        case
         when Routing.BillOfOperationsVariant is null then cast (SUBSTRING( routingReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(Routing.BillOfOperationsVariant as plnal)
         end   as BillOfOperationsVariant,

        case
          when Routing.BillOfOperationsVersion is null then cast (SUBSTRING( routingReference.ChangeRecordReference, 12, 4) as plnversn)
          else cast(Routing.BillOfOperationsVersion as plnversn)
          end  as BillOfOperationsVersion,
        routingReference.ChangeRecordUUID,
        routingReference.ChangeRecordReferenceType,
        routingReference.ChangeRecordReferenceSubtype,
        routingReference.ChangeRecordRefObjectUUID,
        routingReference.ChangeRecordReference,
        routingReference.ParentChangeRecordRefUUID,
        routingReference.IsMainReference,
        @Semantics.user.createdBy: true
        routingReference.CreatedByUser,
        routingReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        routingReference.LastChangedByUser,
        routingReference.LastChangeDateTime,
        routingReference.ChangeRecordItemRelevance,
        routingReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: true
        Routing.Plant,
        @ObjectModel.readOnly: true
        Routing.OrderID,
       routingReference. ChangeRecordItemProcgStatus,
        routingReference.ChgRecdItmTgtSts,
        routingReference.ChgRecdItmDSgntr,
        routingReference.ChgRecdCurrentItemProcgStatus,
        routingReference.ChgRecdReasonForChange,
        routingReference.ExpdCompltnDte,
        routingReference.ChgRecdAuthznGrpText,
        routingReference.ChgRecdNmbrChgSts,
        routingReference.ChangeNumber,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
      Routing.OrderID                            <> ''
  /* Setting to reference type OSR to avoid order specific routings from Routing of
      type ROU getting created here as Routing(type ROU) also stores both master and order specific routings */
  and routingReference.ChangeRecordReferenceType =  'OSR'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHGRECDREFROUTINGBSC",
"I_PRODUCTIONROUTINGVERSION"
],
"ASSOCIATED":
[
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/