I_ChgRecdRefInspectionPlanTP

@AbapCatalog.sqlViewName: 'ICRREFINPTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Change Record Ref Object Inspection Plan TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFINP_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true

define view I_ChgRecdRefInspectionPlanTP
  as select from           I_ChgRecdRefInspectionPlanBsc as inspectionPlanReference
    left outer to one join I_BillOfOperations            as InspectionPlan on  inspectionPlanReference.ChgRecRefInternalKey1 = InspectionPlan.BillOfOperationsType
                                                                           and inspectionPlanReference.ChgRecRefInternalKey2 = InspectionPlan.BillOfOperationsGroup
                                                                           and inspectionPlanReference.ChgRecRefInternalKey3 = InspectionPlan.BillOfOperationsVariant
                                                                           
    left outer to one join I_InspectionPlanVersion as _InspectionPlanVersion      on InspectionPlan.BillOfOperationsGroup = _InspectionPlanVersion.InspectionPlanGroup 
                                                                                  and InspectionPlan.BillOfOperationsVariant = _InspectionPlanVersion.InspectionPlan
                                                                                  and InspectionPlan.BillOfOperationsType = _InspectionPlanVersion.BillOfOperationsType
                                                                                  and _InspectionPlanVersion.ValidityStartDate <= $session.system_date 
                                                                                  and _InspectionPlanVersion.ValidityEndDate >= $session.system_date                                                                        

  association [1..1] to I_ChangeRecordDraftTP         as _ChangeRecordTP          on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefInspectionPlanBsc as _InspectionPlanExtension on $projection.ChangeRecordReferenceUUID = _InspectionPlanExtension.ChangeRecordReferenceUUID
  
  
                                                                                  
        {
  key   inspectionPlanReference.ChangeRecordReferenceUUID,
        case
           when InspectionPlan.BillOfOperationsType is null then cast(SUBSTRING( inspectionPlanReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(InspectionPlan.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when InspectionPlan.BillOfOperationsGroup is null then  cast(SUBSTRING( inspectionPlanReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(InspectionPlan.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when InspectionPlan.BillOfOperationsVariant is null then cast (SUBSTRING( inspectionPlanReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(InspectionPlan.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,
         
         _InspectionPlanVersion.InspectionPlanInternalVersion,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter, 
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        inspectionPlanReference.ChangeRecordUUID,
        inspectionPlanReference.ChangeRecordReferenceType,
        inspectionPlanReference.ChangeRecordReferenceSubtype,
        inspectionPlanReference.ChangeRecordRefObjectUUID,
        inspectionPlanReference.ChangeRecordReference,
        inspectionPlanReference.ParentChangeRecordRefUUID,
        inspectionPlanReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,
        
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        inspectionPlanReference.CreatedByUser,
        inspectionPlanReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        inspectionPlanReference.LastChangedByUser,
        inspectionPlanReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        inspectionPlanReference.ChangeRecordItemRelevance,
        inspectionPlanReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        inspectionPlanReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        inspectionPlanReference.ChgRecdCurrentItemProcgStatus,
        inspectionPlanReference.ChangeNumber,
         @ObjectModel.readOnly: true
        inspectionPlanReference.ChgRecdItmTgtSts,
         @ObjectModel.readOnly: true
        inspectionPlanReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
        
}
where
  InspectionPlan.BillOfOperationsType = 'Q' or
  InspectionPlan.BillOfOperationsType is null 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFINSPECTIONPLANBSC",
"I_INSPECTIONPLANVERSION"
],
"ASSOCIATED":
[
"E_CHGRECDREFINSPECTIONPLANBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/