I_ChgRecdRefETOVersBOMTP

@AbapCatalog.sqlViewName: 'ICRREFETOVBOMTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Change Record Ref Obj ETO Vers BOM - TP'

@VDM.viewType: #TRANSACTIONAL
@ObjectModel: { semanticKey: [ 'Material','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant','BillOfMaterialVersion'],
                writeDraftPersistence: 'PLMCRREFEOB_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }

@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}

define view I_ChgRecdRefETOVersBOMTP
  as select from I_ChgRecdRefETOVersBOMBsc  as eto_vers_bom
    left outer to one join I_SalesOrderBOMLink as BOMLink on  eto_vers_bom.ChgRecRefInternalKey1 = BOMLink.Plant
                                                          and eto_vers_bom.ChgRecRefInternalKey2 = BOMLink.BillOfMaterial
                                                          and eto_vers_bom.ChgRecRefInternalKey3 = BOMLink.BillOfMaterialVariant

  association [1..1] to I_ChangeRecordDraftTP        as _ChangeRecordTP  on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID  
{

  key        eto_vers_bom.ChangeRecordReferenceUUID,
             
             case
               when BOMLink.Material is null then cast(substring( eto_vers_bom.ChangeRecordReference, 1, 40) as matnr)
               else cast(BOMLink.Material as matnr)
               end                                                      as Material,
             
             case
              when BOMLink.Plant is null then  cast(substring( eto_vers_bom.ChangeRecordReference, 41, 4) as werks_d)
              else cast(BOMLink.Plant as werks_d)
              end                                                       as Plant,
             
             case
              when BOMLink.BillOfMaterialVariantUsage is null then cast (substring( eto_vers_bom.ChangeRecordReference, 45, 1) as stlan)
              else cast(BOMLink.BillOfMaterialVariantUsage as stlan)
              end                                                       as BillOfMaterialVariantUsage,
             
             case
              when BOMLink.BillOfMaterialVariant is null then cast(substring( eto_vers_bom.ChangeRecordReference, 46, 2) as stalt)
              else cast(BOMLink.BillOfMaterialVariant as stalt)

              end                                                       as BillOfMaterialVariant,
                           
             case 
              when eto_vers_bom.ChgRecRefInternalKey4 is null then cast(substring( eto_vers_bom.ChangeRecordReference, 48, 4) as cs_versn)
              else cast(eto_vers_bom.ChgRecRefInternalKey4 as cs_versn)
             end                                                        as     BillOfMaterialVersion, 
             
             cast( BOMLink.BillOfMaterial as cs_stlnr preserving type ) as BillOfMaterial,
             BOMLink.BillOfMaterialCategory,
             
             BOMLink.SalesOrder,
             BOMLink.SalesOrderItem,
             eto_vers_bom.ChangeRecordUUID,
             @ObjectModel.readOnly: true 
             eto_vers_bom.ChangeRecordReferenceType,
             eto_vers_bom.ChangeRecordReferenceSubtype,
             eto_vers_bom.ChangeRecordRefObjectUUID,
             eto_vers_bom.ChangeRecordReference,
             eto_vers_bom.ParentChangeRecordRefUUID,
             eto_vers_bom.IsMainReference,
             @Semantics.user.createdBy: true
             @ObjectModel.readOnly: true
             eto_vers_bom.CreatedByUser,
             eto_vers_bom.CreationDateTime,
             @Semantics.user.lastChangedBy: true
             @ObjectModel.readOnly: true
             eto_vers_bom.LastChangedByUser,
             eto_vers_bom.LastChangeDateTime, 
             eto_vers_bom.ChangeRecordItemRelevance,
             eto_vers_bom.ChangeRecordVirtualRefInd,
             eto_vers_bom.ChgRecdReasonForChange,
             eto_vers_bom.ExpdCompltnDte,
             eto_vers_bom.ChgRecdAuthznGrpText,
             eto_vers_bom.ChgRecdNmbrChgSts,
             eto_vers_bom.ChangeNumber,      
             eto_vers_bom.ChangeRecordItemProcgStatus,
             eto_vers_bom.ChgRecdCurrentItemProcgStatus,
             eto_vers_bom.ChgRecdItmTgtSts,
             eto_vers_bom.ChgRecdItmDSgntr,
             
             @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
             _ChangeRecordTP

}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHGRECDREFETOVERSBOMBSC",
"I_SALESORDERBOMLINK"
],
"ASSOCIATED":
[
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/