I_ChgRecdFuncLocTskListTP

@AbapCatalog.sqlViewName: 'ICRREFFTLTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Chg Red Ref Obj Func Loc Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFFTL_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
define view I_ChgRecdFuncLocTskListTP
  as select from           I_ChgRecdFuncLocTskListBsc as FuncLocTaskListReference
    left outer to one join I_BillOfOperations         as FuncLocTaskList on  FuncLocTaskListReference.ChgRecRefInternalKey1 = FuncLocTaskList.BillOfOperationsType
                                                                         and FuncLocTaskListReference.ChgRecRefInternalKey2 = FuncLocTaskList.BillOfOperationsGroup
                                                                         and FuncLocTaskListReference.ChgRecRefInternalKey3 = FuncLocTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP           on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdFuncLocTskListBsc as _FuncLocTaskListExtension on $projection.ChangeRecordReferenceUUID = _FuncLocTaskListExtension.ChangeRecordReferenceUUID
{
  key   FuncLocTaskListReference.ChangeRecordReferenceUUID,
        case
           when FuncLocTaskList.BillOfOperationsType is null then cast(SUBSTRING( FuncLocTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(FuncLocTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when FuncLocTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( FuncLocTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(FuncLocTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when FuncLocTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( FuncLocTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(FuncLocTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        FuncLocTaskListReference.ChangeRecordUUID,
        FuncLocTaskListReference.ChangeRecordReferenceType,
        FuncLocTaskListReference.ChangeRecordReferenceSubtype,
        FuncLocTaskListReference.ChangeRecordRefObjectUUID,
        FuncLocTaskListReference.ChangeRecordReference,
        FuncLocTaskListReference.ParentChangeRecordRefUUID,
        FuncLocTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,        
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        FuncLocTaskListReference.CreatedByUser,
        FuncLocTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        FuncLocTaskListReference.LastChangedByUser,
        FuncLocTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        FuncLocTaskListReference.ChangeRecordItemRelevance,
        FuncLocTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        FuncLocTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        FuncLocTaskListReference.ChgRecdCurrentItemProcgStatus,
        FuncLocTaskListReference.ChangeNumber,
        @ObjectModel.readOnly: true
        FuncLocTaskListReference.ChgRecdItmTgtSts,
        @ObjectModel.readOnly: true
        FuncLocTaskListReference.ChgRecdItmDSgntr,
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
        
}
where
     FuncLocTaskList.BillOfOperationsType = 'T'
  or FuncLocTaskList.BillOfOperationsType is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDFUNCLOCTSKLISTBSC"
],
"ASSOCIATED":
[
"E_CHGRECDFUNCLOCTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/