I_ChgImpactBOMItem

@AbapCatalog.sqlViewName: 'ICHGIMPBOMITM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MASTER}
@EndUserText.label: 'Bill of Material Items'
define view I_ChgImpactBOMItem
  as select from I_BillOfMaterialItem as BOMItem
    inner join I_MaterialBOM as MatlBOM on BOMItem.BillOfMaterial = MatlBOM.BillOfMaterial
                                                    and BOMItem.BillOfMaterialCategory = MatlBOM.BillOfMaterialCategory
                                                    and BOMItem.BillOfMaterialVariant  = MatlBOM.BillOfMaterialVariant
                                                    and BOMItem.BillOfMaterialVersion  = MatlBOM.BillOfMaterialVersion
    left outer to one join I_UnitizedMaterial   as UnitizedMatl on MatlBOM.Material = UnitizedMatl.Material

    left outer to one join I_MaterialText       as MaterialText on  BOMItem.BillOfMaterialComponent = MaterialText.Material
                                                                and MaterialText.Language           = $session.system_language

{

      //BOMItem

  key BOMItem.BillOfMaterial,
  key BOMItem.BillOfMaterialCategory,
  key BOMItem.BillOfMaterialVariant,
  key BOMItem.BillOfMaterialVersion,
  key BillOfMaterialItemNodeNumber,
  key BOMItemInternalChangeCount,
      BillOfMaterialItemUUID,
      ValidityStartDate,
      ValidityEndDate,
      BOMItem.EngineeringChangeDocument,
      BOMItem.ChgToEngineeringChgDocument,
      InheritedNodeNumberForBOMItem,
      //For Non versioned BOMs the inherited node number version BOM can be the same as

      //Inherited Node number for BOM item

      case
      when InheritedNodeNumberVersionBOM is not initial
      then InheritedNodeNumberVersionBOM
      else InheritedNodeNumberForBOMItem
      end as InheritedNodeNumberVersionBOM,

      // Header Material

      MatlBOM.Material,
      //Plant of the BOM. Added in 2021 for MRS Designator retrieval purposes

      MatlBOM.Plant,
      MatlBOM.BillOfMaterialVariantUsage,

      //Effectivity type and complex assembly type in case of unitized material

      UnitizedMatl.EffectivityType,
      UnitizedMatl.ComplexAssemblyType,

      //Check if the Material is unitized or Not

      case
        when EffectivityType is not null
            then  cast('X' as mpe_cima_untz_matl_ind_type preserving type )
        else cast('' as mpe_cima_untz_matl_ind_type preserving type )
      end as IsMaterialUnitized,

      BOMItemRecordCreationDate,
      BOMItemCreatedByUser,
      BOMItemLastChangeDate,
      BOMItemLastChangedByUser,
      BillOfMaterialComponent,
      MaterialText.MaterialName,
      BillOfMaterialItemCategory,
      BillOfMaterialItemNumber,
      BillOfMaterialItemUnit,
      BillOfMaterialItemQuantity,
      IsAssembly,
      IsSubItem,
      BOMItemSorter,
      FixedQuantity,
      PurchasingGroup,
      Currency,
      MaterialComponentPrice,
      IdentifierBOMItem,
      MaterialPriceUnitQty,
      ComponentScrapInPercent,
      OperationScrapInPercent,
      IsNetScrap,
      NumberOfVariableSizeItem,
      QuantityVariableSizeItem,
      FormulaKey,
      BOMItemDescription,
      BOMItemText2,
      BOMItem.MaterialGroup,
      DocumentType,
      DocNumber,
      DocumentVersion,
      DocumentPart,
      ClassNumber,
      ClassType,
      ResultingItemCategory,
      DependencyObjectNumber,
      ObjectType,
      IsClassificationRelevant,
      IsBulkMaterial,
      BOMItemIsSparePart,
      BOMItemIsSalesRelevant,
      IsProductionRelevant,
      BOMItemIsPlantMaintRelevant,
      BOMItemIsCostingRelevant,
      IsEngineeringRelevant,
      SpecialProcurementType,
      IsBOMRecursiveAllowed,
      OperationLeadTimeOffset,
      OpsLeadTimeOffsetUnit,
      IsMaterialProvision,
      BOMIsRecursive,
      BOMItem.DocumentIsCreatedByCAD,
      DistrKeyCompConsumption,
      DeliveryDurationInDays,
      Creditor,
      CostElement,
      Size1,
      Size2,
      Size3,
      UnitOfMeasureForSize1To3,
      GoodsReceiptDuration,
      PurchasingOrganization,
      RequiredComponent,
      MultipleSelectionAllowed,
      ProdOrderIssueLocation,
      MaterialIsCoProduct,
      ExplosionType,
      AlternativeItemGroup,
      FollowUpGroup,
      DiscontinuationGroup,
      IsConfigurableBOM,
      ReferencePoint,
      LeadTimeOffset,
      IsSoftwareComponent,
      ProductionSupplyArea,
      IsDeleted,
      BOMItem.IsALE,
      BillOfMaterialItemCategoryDesc,
      MaterialComponentIsPhantomItem,
      IsPhantomItem,
      /* Associations */

      //BOMItem

      _BOMItemCategory,
      _Currency,
      _Dost,
      _Eqst,
      _Mast,
      _Prst,
      _Stst,
      _Tpst,
      BOMItem._UnitOfMeasure

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFMATERIALITEM",
"I_MATERIALBOM",
"I_MATERIALTEXT",
"I_UNITIZEDMATERIAL"
],
"ASSOCIATED":
[
"I_BILLOFMATERIALITEMCATEGORY",
"I_CURRENCY",
"I_DOCUMENTBOMLINK",
"I_EQST",
"I_MATERIALBOMLINK",
"I_PRST",
"I_STST",
"I_TPST",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_BILLOFMATERIALITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/