I_ChemicalRoot

@EndUserText.label: 'Chemical Root'
@Analytics: { dataCategory:#DIMENSION , dataExtraction.enabled:true }
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'ChemicalUUID'
@Metadata.allowExtensions:true 

@AccessControl.authorizationCheck: #CHECK

@AbapCatalog.sqlViewName: 'ICHMROOT'
@AbapCatalog.compiler.compareFilter: true

// Client handling by session 

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MASTER } 
                         
define view I_ChemicalRoot
  as select from ehfndd_chm_root

  association [0..1] to I_User             as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User             as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..*] to I_ChemicalRevision as _ChemicalRevision  on $projection.ChemicalUUID = _ChemicalRevision.ChemicalUUID
  association [1..1] to I_ChemicalType     as _ChemicalType      on $projection.ChemicalType = _ChemicalType.ChemicalType

{
  key cast( db_key as ehfnd_chm_uuid_ref preserving type ) as ChemicalUUID,
      _ChemicalRevision,

      id                                  as ChemicalID,

      @ObjectModel.foreignKey.association: '_ChemicalType'
      chm_nature                          as ChemicalType,
      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _ChemicalType,


      // Admin data

      datetime_cr                         as CreationDateTime,
      user_id_cr                          as CreatedByUser,
      _CreatedByUser,
      datetime_ch                         as LastChangeDateTime,
      user_id_ch                          as LastChangedByUser,
      _LastChangedByUser

}                        
  
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDD_CHM_ROOT"
],
"ASSOCIATED":
[
"I_CHEMICALREVISION",
"I_CHEMICALTYPE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/