I_ChangeRecordReferenceSpecTP

@AbapCatalog.sqlViewName: 'ICHGRECREFSPECTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.preserveKey:true
@ObjectModel: { semanticKey: ['Specification'],
                writeDraftPersistence: 'PLMCRREFSPEC_D',
                createEnabled : 'EXTERNAL_CALCULATION',
                deleteEnabled : 'EXTERNAL_CALCULATION',
                updateEnabled : 'EXTERNAL_CALCULATION'
              }
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType: { serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #XXL}
@EndUserText.label: 'Change Record Reference Specification'
define view I_ChangeRecordReferenceSpecTP
  as select from    I_ChgRecdRefSpecBsc        as reference_SPC
    left outer join I_SpecificationNonHistoric as _Specification on reference_SPC.ChgRecRefInternalKey1 = _Specification.SpecificationInternalID
  association [1..1] to I_ChangeRecordDraftTP   as _ChangeRecord  on $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
  association [0..1] to I_SpecIdfrBscForKeyDate as _Identifier    on $projection.SpecificationInternalID = _Identifier.SpecificationInternalID
  association [0..1] to E_ChgRecdRefSpecBsc     as _SpecExtension on $projection.ChangeRecordReferenceUUID = _SpecExtension.ChangeRecordReferenceUUID
{
  key ChangeRecordReferenceUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case when _Specification.Specification is null then cast(ChangeRecordReference as esesubid)
      else cast( _Specification.Specification as esesubid)
      end                  as Specification,
      _Specification.SpecificationInternalID,

      // this field is present for compatibility reasons; identifier association should NOT be resolved here

      cast('' as eseident) as SpecIdfgDescText,
      //_Identifier(P_KeyDate : $session.system_date).SpecIdfgDescText,


      ChangeRecordUUID,
      ChangeRecordReferenceType,
      ChangeRecordReferenceSubtype,
      ChangeRecordRefObjectUUID,
      ChangeRecordReference,
      ParentChangeRecordRefUUID,
      IsMainReference,
      ChgRecdReasonForChange,
      ExpdCompltnDte,
      ChgRecdAuthznGrpText,
      ChgRecdNmbrChgSts,
      ChangeNumber,
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      CreatedByUser,
      CreationDateTime, 
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      LastChangedByUser,
      LastChangeDateTime,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ChangeRecordItemRelevance,
      ChangeRecordVirtualRefInd,
      _Specification.SpecificationType,
      //      Customer,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      reference_SPC.ChangeRecordItemProcgStatus,
      @ObjectModel.readOnly: true
      reference_SPC.ChgRecdCurrentItemProcgStatus,
      @ObjectModel.readOnly: true
      ChgRecdItmTgtSts,
      @ObjectModel.readOnly: true
      ChgRecdItmDSgntr,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChangeRecord,
      _SpecificationType
}; 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHGRECDREFSPECBSC",
"I_SPECIFICATIONNONHISTORIC"
],
"ASSOCIATED":
[
"E_CHGRECDREFSPECBSC",
"I_CHANGERECORDDRAFTTP",
"I_SPECIDFRBSCFORKEYDATE",
"I_SPECTYPE"
],
"BASE":
[
"I_SPECIFICATIONNONHISTORIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/