I_ChangeRecordRefOrderBOMTP

@AbapCatalog.sqlViewName: 'ICHGRECREFOBMTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Change Record Ref Object Order BOM - TP'
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
semanticKey: [ 'Material','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant'],
                writeDraftPersistence: 'PLMCRREFOBM_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }

@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #XXL}
@AbapCatalog.preserveKey:true
define view I_ChangeRecordRefOrderBOMTP
  as select from           I_ChangeRecordRefOrderBOMBsc as reference_bom

    left outer to one join I_SalesOrderBOMLink          as BOMLink on  reference_bom.ChgRecRefInternalKey1 = BOMLink.BillOfMaterialCategory
                                                                   and reference_bom.ChgRecRefInternalKey2 = BOMLink.BillOfMaterial
                                                                   and reference_bom.ChgRecRefInternalKey3 = BOMLink.BillOfMaterialVariant

  association [1..1] to I_ChangeRecordDraftTP        as _ChangeRecordTP  on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChangeRecordRefOrderBOMBsc as _OrdBOMExtension on $projection.ChangeRecordReferenceUUID = _OrdBOMExtension.ChangeRecordReferenceUUID
{

  key        reference_bom.ChangeRecordReferenceUUID,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
               when BOMLink.Material is null then cast(substring( reference_bom.ChangeRecordReference, 1, 40) as matnr)
               else cast(BOMLink.Material as matnr)
               end                                                      as Material,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.Plant is null then  cast(substring( reference_bom.ChangeRecordReference, 41, 4) as werks_d)
              else cast(BOMLink.Plant as werks_d)
              end                                                       as Plant,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.BillOfMaterialVariantUsage is null then cast (substring( reference_bom.ChangeRecordReference, 45, 1) as stlan)
              else cast(BOMLink.BillOfMaterialVariantUsage as stlan)
              end                                                       as BillOfMaterialVariantUsage,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.BillOfMaterialVariant is null then cast(substring( reference_bom.ChangeRecordReference, 46, 2) as stalt)
              else cast(BOMLink.BillOfMaterialVariant as stalt)

              end                                                       as BillOfMaterialVariant,
              
             BOMLink.SalesOrder                                         as SalesOrder,
             BOMLink.SalesOrderItem                                     as SalesOrderItem,
             reference_bom.ChangeRecordUUID,

             reference_bom.ChangeRecordReferenceType,
             reference_bom.ChangeRecordReferenceSubtype,
             reference_bom.ChangeRecordReference,
             reference_bom.ParentChangeRecordRefUUID,
             reference_bom.IsMainReference,
             //             BOMLink.BillOfMaterialCategory,

             cast(reference_bom.ChgRecRefInternalKey1 as stlty)               as BillOfMaterialCategory,
             reference_bom.ChangeNumber,
             @Semantics.user.createdBy: true
             reference_bom.CreatedByUser,
             reference_bom.CreationDateTime,
             @Semantics.user.lastChangedBy: true
             reference_bom.LastChangedByUser,
             reference_bom.LastChangeDateTime,
             ChgRecdReasonForChange,
             ExpdCompltnDte,
             ChgRecdAuthznGrpText,
             ChgRecdNmbrChgSts,


             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             reference_bom.ChangeRecordItemRelevance,
             reference_bom.ChangeRecordVirtualRefInd,

             //For BOM Navigation

             cast( BOMLink.BillOfMaterial as cs_stlnr preserving type ) as BillOfMaterial,
             reference_bom.ChangeRecordRefObjectUUID,
             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             reference_bom.ChangeRecordItemProcgStatus,
             @ObjectModel.readOnly: true
             reference_bom.ChgRecdCurrentItemProcgStatus,
             @ObjectModel.readOnly: true
             reference_bom.ChgRecdItmTgtSts,
             @ObjectModel.readOnly: true
             reference_bom.ChgRecdItmDSgntr,
             @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
             _ChangeRecordTP

}
where
  reference_bom.ChangeRecordReferenceType = 'OBM'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGERECORDREFORDERBOMBSC",
"I_SALESORDERBOMLINK"
],
"ASSOCIATED":
[
"E_CHANGERECORDREFORDERBOMBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/