I_ChangeRecdRefInspPlanTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFINPTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Change Record Reference Object Inspection Plan'
define view I_ChangeRecdRefInspPlanTP_2
  as select from           I_ChgRecdRefInspectionPlanBsc as reference_inp
    left outer to one join I_BillOfOperations            as InspectionPlan on  reference_inp.ChgRecRefInternalKey1 = InspectionPlan.BillOfOperationsType
                                                                           and reference_inp.ChgRecRefInternalKey2 = InspectionPlan.BillOfOperationsGroup
                                                                           and reference_inp.ChgRecRefInternalKey3 = InspectionPlan.BillOfOperationsVariant
  association        to parent I_ChangeRecordTP_2     as _ChangeRecordAPITP       on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP         as _ChangeRecordTP          on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefInspectionPlanBsc as _InspectionPlanExtension on $projection.ChangeRecordReferenceUUID = _InspectionPlanExtension.ChangeRecordReferenceUUID
{
  key   reference_inp.ChangeRecordReferenceUUID,
        case
           when InspectionPlan.BillOfOperationsType is null then cast(SUBSTRING( reference_inp.ChangeRecordReference, 1, 1) as plnty)
           else cast(InspectionPlan.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        case
        when InspectionPlan.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_inp.ChangeRecordReference, 2, 9) as plnnr)
        else cast(InspectionPlan.BillOfOperationsGroup as plnnr)
        end                             as InspectionPlanGroup,

        case
         when InspectionPlan.BillOfOperationsVariant is null then cast (SUBSTRING( reference_inp.ChangeRecordReference, 10, 2) as plnal)
         else cast(InspectionPlan.BillOfOperationsVariant as plnal)
         end                            as InspectionPlan,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        //cast ('00000000' as plantext )  as BillOfOperationsDesc,


        reference_inp.ChangeRecordUUID,
        reference_inp.ChangeRecord,
        reference_inp.ChangeRecordReferenceType,
        reference_inp.ChangeRecordReferenceSubtype,
        reference_inp.ChangeRecordRefObjectUUID,
        reference_inp.ChangeRecordReference,
        reference_inp.ParentChangeRecordRefUUID,
        reference_inp.IsMainReference,
        reference_inp.CreatedByUser,
        reference_inp.CreationDateTime,
        reference_inp.LastChangedByUser,
        reference_inp.LastChangeDateTime,
        reference_inp.ChangeRecordItemRelevance,
        reference_inp.ChangeRecordVirtualRefInd,
        reference_inp.ChangeRecordItemProcgStatus,
        _ChangeRecordTP,
        _ChangeRecordAPITP
}
where
  InspectionPlan.BillOfOperationsType = 'Q' or
  InspectionPlan.BillOfOperationsType is null 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFINSPECTIONPLANBSC"
],
"ASSOCIATED":
[
"E_CHGRECDREFINSPECTIONPLANBSC",
"I_CHANGERECORDDRAFTTP",
"I_CHANGERECORDTP_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/