I_CapacityRequirementOrignText

@AbapCatalog.sqlViewName: 'IPPCAPRQMTORTXT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'CapacityRequirementOrigin'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #META}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Capacity Requirement Origin - Text'

/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view I_CapacityRequirementOrignText
  as select from dd07t as txt
  association [0..1] to I_Language                  as _Language                  on $projection.Language = _Language.Language
  association [1..1] to I_CapacityRequirementOrigin as _CapacityRequirementOrigin on $projection.CapacityRequirementOrigin = _CapacityRequirementOrigin.CapacityRequirementOrigin 
{
      @ObjectModel.foreignKey.association: '_CapacityRequirementOrigin'
      @ObjectModel.text.element: ['CapacityRequirementOriginName']
  key cast(substring(txt.domvalue_l, 1, 1) as capacityrequirementorigin preserving type) as CapacityRequirementOrigin,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast(txt.ddlanguage as spras preserving type) as Language,
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(txt.ddtext as capacityrequirementoriginname preserving type) as CapacityRequirementOriginName,
      @Analytics.hidden: true
      @Consumption.hidden: true
      txt.domvalue_l as DomainValue,

      // Associations

      _Language,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT] 
      _CapacityRequirementOrigin
}
  where domname = 'TYPKZ' and
        as4local = 'A'    and
        as4vers  = '0000';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_CAPACITYREQUIREMENTORIGIN",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/